Scripted Application Build  The Micro Focus Environment http://www.simotime.com  Copyright © 1987-2010 SimoTime Enterprises  All Rights Reserved

Introduction
(Next) (Previous) (Table-of-Contents)

This document is an introduction or overview of the scripted application build process for an application that has been moved from a Mainframe System to a Windows system running a Micro Focus sub-system such as Enterprise Server, Application Server or Net Express.

A scripted build process may be a requirement in larger environments. A predefined and documented process for doing the build of a production system without operator intervention is a minimum requirement for the audit or validation process.

A scripted application build should be a repeatable process with an audit or validation trail. The process should be executable as an automated, unattended process. Requiring operator input during the application build process introduces an exposure point for error.

The sample process described in this document will display information to the console and write information to a log file based on the results of the execution of the compile and/or generate processes. The sample process will focus on building a production system for the ASCII-encoded environment.

This document addresses the requirement of doing a scripted build of the executable members from source members. It does not address the requirement of converting mainframe, EBCDIC-encoded data to non-mainframe, ASCII-encoded data. Information about data conversion is available in separate documents.

Quick Start
(Next) (Previous) (Table-of-Contents)

This section provides a minimal amount of information to get started with the scripted application build process.

Quick Start, System
(Next) (Previous) (Table-of-Contents)

The following table shows a summary of the four (4) possible steps (or command files) involved in doing a build of a batch and online system.

The preceding command files are discussed in more detail in the following sections of this document.

Quick Start, Batch
(Next) (Previous) (Table-of-Contents)

The "GenerateBMSascForSam1Online.CMD" command file will be used to compile the COBOL programs used by the batch applications. The command may be executed from Windows Explorer, called by another command file or from within a Windows Command prompt screen. The following show the command line syntax.

C:\SimoSam1\Adm1> CompileGNTascForSam1Batch

The program will first call Env1Base to set the environment variables used by the various application build functions. Next, the Windows "FOR" command is used to loop through the records in a file that contains a list of batch COBOL program names. For each record in the file a call to the command file "zCompileToGNTs01.CMD" will be made to do the actual compile. Depending on the results of the compile a "normal end-of-job" or "abnormal termination" message will be displayed and posted to the log file.

The default directives are specified in the OS390AscBatch.DIR file located in the "DIRS" sub-directory. The directives in this file are used unless a directives file with the same name as the program is found in the "DIRS" subdirectory.

For this example the load member is placed in the StagLibA sub-directory.

Quick Start, Online
(Next) (Previous) (Table-of-Contents)

Creating the load members for the online environment is a three (3) step process. The third step is optional depending on the use of non-executable tables and the EXEC CICS LOAD command.

Note: the third step of the preceding list is optional depending on the use of the EXEC CICS LOAD command to load non-executable members (i.e. data tables).

Quick Start, Online, BMS Generation
(Next) (Previous) (Table-of-Contents)

BMS load member and COBOL copy file for the BMS screens used by the online application. The command may be executed from Windows Explorer, called by another command file or from within a Windows Command prompt screen. The following show the command line syntax.

C:\SimoSam1\Adm1> GenerateBMSascForSam1Online

The command will first call Env1Base to set the environment variables used by the various application build functions. Next, the Windows "FOR" command is used to loop through the records in a file that contains a list of source code for the BMS members. For each record in the file a call to the command file "GenerateBMSascForSam1Online.CMD" will be made to do the actual BMS generation. Depending on the results of the generation a "normal end-of-job" or "abnormal termination" message will be displayed and posted to the log file.

For this example the load member is placed in the StagLibA sub-directory and the COBOL copy file is placed in the CobCpy6 sub-directory.

Quick Start, Online, Compile the COBOL Programs
(Next) (Previous) (Table-of-Contents)

The "GenerateBMSascForSam1Online.CMD" command file will be used to compile the COBOL programs used by the online applications. The command may be executed from Windows Explorer, called by another command file or from within a Windows Command prompt screen. The following show the command line syntax.

C:\SimoSam1\Adm1> CompileGNTascForSam1Online

The program will first call Env1Base to set the environment variables used by the various application build functions. Next, the Windows "FOR" command is used to loop through the records in a file that contains a list of online COBOL program names. For each record in the file a call to the command file "zCompileToGNTs01.CMD" will be made to do the actual compile. Depending on the results of the compile a "normal end-of-job" or "abnormal termination" message will be displayed and posted to the log file.

The default directives are specified in the OS390AscOnline.DIR file located in the "DIRS" sub-directory. The directives in this file are used unless a directives file with the same name as the program is found in the "DIRS" subdirectory.

For this example the load members are placed in the StagLibA sub-directory.

Quick Start, Online, Generate the non-Executable Members
(Next) (Previous) (Table-of-Contents)

The "GenrateMODascForSam1Online.CMD" command file will be used to generate the non-executable load members used by the online applications. The command may be executed from Windows Explorer, called by another command file or from within a Windows Command prompt screen. The following show the command line syntax.

C:\SimoSam1\Adm1> CompileMODascForSam1Online

The script will first call Env1Base to set the environment variables used by the various application build functions. Next, the Windows "FOR" command is used to loop through the records in a file that contains a list of online Mainframe Assembler source members that use the DC statement to define non-executable tables. For each record in the file a call to the command file "zModGeneration01.CMD" will be made to do the actual generation. Depending on the results of the generation a "normal end-of-job" or "abnormal termination" message will be displayed and posted to the log file.

For this example the load members are placed in the StagLibA sub-directory.

Advanced Functions
(Next) (Previous) (Table-of-Contents)

This section provides additional detail about the tasks included in the scripted application build process.

Advanced Functions, System
(Next) (Previous) (Table-of-Contents)

The application build may be done on a development server with the executable members being placed in a staging area to be picked up by (or forwarded to) the system test group. This approach works well for small to mid-range environments. However, as the application grows in size and complexity additional controls or processes are required to insure that the executables going to production are built from a known base of source code. This includes all the side files for compiler options, directives and other specifications that will affect the behavior of the executables going into production.

In order to accomplish this it becomes necessary for the development group to submit the source code and control files to the test group. The first phase of the application or system testing will be to do a scripted build of the application and validate the results of the build process. Once the executables are generated the normal testing cycle begins.

Advanced Functions, Compiling the Batch Programs
(Next) (Previous) (Table-of-Contents)

The following is a listing of the command file (CompileGNTascForSam1Batch.CMD) that does the multiple compilations of the COBOL programs for the batch environment. This script will read a file that contains a list of COBOL source members and call the "zCompileToGnts01.CMD" to do the actual generation for each source member in the list.

@echo OFF
rem  * ************************************************************************
rem  * This procedure calls the following Windows Command Files.
rem  * 1. Env1Base.CMD - this provides a single point for setting commonly
rem  *    used environment variables.
rem  * 2. SimoNOTE.CMD - this provides a consistent process for displaying
rem  *    messages to the screen and writing to a journal or log file.
rem  * 3. zCompileToGnts01.CMD - this will do the actual compile of the
rem  *    specified program.
rem  * ************************************************************************
     setlocal
     call ..\Env1Base
     set CmdName=CompileGNTascForSam1Batch
rem  *
     call SimoNOTE "****************************************%CmdName%.CMD"
     call SimoNOTE "Starting JobName %CmdName%.CMD"
rem  *
rem  * Set the environment variable to use the Active01.DIR directives file
rem  * as the default.
     set zDIRS=%BaseLib1%\DIRS\OS390AscBatch.DIR
rem  * The following two statements will set the environment variables to
rem  * a "Y" for Yes or "N" for No. A "Y" will cause the function to be
rem  * performed by the called procedure. An "N" value will not perform the
rem  * function.
     set EraseAfter=N
     set TransferGNT=N
rem  *
rem  * Read the ListSam1CobolBatchLessExt.TXT file and pass the contents of each record to the
rem  * command file that does the actual compile. Each record in the file
rem  * contains an eight character program name.
     for /F %%i in (ListSam1CobolBatchLessExt.TXT) do CALL zCompileToGNTs01 %%i COBOL StagLibA
rem  *
     call SimoNOTE "Finished JobName %CmdName%.CMD"
     if not "%SimoGENS%" == "BATCH" pause
     endlocal

Advanced Functions, Build Online Load Members
(Next) (Previous) (Table-of-Contents)

The following sections of this document contain various listings of the command file that do generations or compilations of user-written source code for an ASCII-encoded, online environment.

Advanced Functions, Generate BMS Screens
(Next) (Previous) (Table-of-Contents)

The following is a listing of the command file (GenerateBMSascForSam1Online.CMD) that does the multiple generations of the BMS executable and COBOL copy file for the online environment. This script will read a file that contains a list of BMS source members and call the "zBmsGeneration01.CMD" to do the actual BMS generation for each source member in the list.

@echo OFF
rem  * ************************************************************************
rem  * This procedure calls the following Windows Command Files.
rem  * 1. Env1Base.CMD - this provides a single point for setting commonly
rem  *    used environment variables.
rem  * 2. SimoNOTE.CMD - this provides a consistent process for displaying
rem  *    messages to the screen and writing to a journal or log file.
rem  * 3. zBmsGeneration01.CMD - this will do the actual generation of the
rem  *    specified member.
rem  * ************************************************************************
     setlocal
     call ..\Env1Base
     set CmdName=GenerateBMSascForSam1Online
rem  *
     call SimoNOTE "****************************************%CmdName%.CMD"
     call SimoNOTE "Starting JobName %CmdName%.CMD"
rem  *
rem  * The following two statements will set the environment variables to
rem  * a "Y" for Yes or "N" for No. A "Y" will cause the function to be
rem  * performed by the called procedure. An "N" value will not perform the
rem  * function.
     set EraseAfter=N
     set TransferBMS=N
rem  *
rem  * Read the ListSam1BmsLessExt.TXT file and pass the contents of each record to the
rem  * command file that does the actual compile. Each record in the file
rem  * contains an eight character program name. The following parameters are
rem  * passed to the called command file.
rem  * Parameter  Description
rem  * ---------  ------------------------------------------------------------
rem  *    1       Name of source member
rem  *    2       Name of source directory relative to BaseLib1
rem  *    3       Name of directory for load member relative to BaseLib1
rem  *
     for /F %%i in (ListSam1BmsLessExt.TXT) do CALL zBmsGeneration01 %%i BMS StagLibA
rem  *
     call SimoNOTE "Finished JobName %CmdName%.CMD"
     if not "%SimoGENS%" == "BATCH" pause
     endlocal

The following is the command file (zBmsGeneration01.CMD) that does a single BMS generation from a single BMS source member. This command file is usually called from the "GenerateBMSascForSam1Online.CMD" command file.

@echo OFF
     echo Parameter 1 is %1
     echo CobCpy is %CobCpy%
     set Compile2GNTStatus=0000
rem  *
rem  * It is the callers reponsibility to set BaseLib1 to the base
rem  * directory. This procedure uses various sub-directories under the
rem  * base directory.
rem  *
rem  * The following parameters are received from the calling command file.
rem  * Parameter  Description
rem  * ---------  ------------------------------------------------------------
rem  *    1       Name of source member
rem  *    2       Name of source directory relative to BaseLib1
rem  *    3       Name of directory for load member relative to BaseLib1
rem  *    Note    The COBOL copy file will be written to the CobCpy6
rem  *            sub-directory inder the BaseLib1 directory.
rem  *
     call SimoNOTE "* ------------------------------------------------------------*zBmsGeneration01"
     call SimoNOTE "Starting JobStep zBmsGeneration01, Status is %Compile2GNTStatus%, Program is %1"
rem  *
rem  * ************************************************************************
rem  * Do the BMS generation to create the .MOD Screen load member and the
rem  * copy file to be used by a COBOL program.
rem  * The copy file will be written to the CobCpy6 sub-directory under the
rem  * base directory.
     mfbmscl %BaseLib1%\%2\%1.BMS /SYSPARM=MAP /SYSPARM=DSECT /COBOL=%BaseLib1%\CobCpy6\ /BINARY=%BaseLib1%\%3\
     if not ERRORLEVEL = 0 set Compile2GNTStatus=0010
     if not "%Compile2GNTStatus%" == "0000" goto :Compile2GNTNOK
rem  *
     echo %BaseLib1%\%3\%1.MOD
     if exist %BaseLib1%\%3\%1.MOD goto :Compile2GNTAOK
     set Compile2GNTStatus=0020
     goto :Compile2GNTNOK
rem  *
rem  * ************************************************************************
:Compile2GNTAOK
     if "%TransferBms%"=="Y"  (echo Transfer GNT is ENABLED
                               COPY /Y %BaseLib1%\%3\%1.GNT %BaseLib1%\ProdLib1\%1.GNT)
     if "%EraseAfter%"=="Y"   (echo Erase After is ENABLED
                               ERASE %BaseLib1%\%3\%1.GNT)
     call SimoNOTE "Complete JobStep zBmsGeneration01, Status is %Compile2GNTStatus%, Program is %1"
     goto :End
rem  *
rem  * ************************************************************************
:Compile2GNTNOK
     set JobStatus=%Compile2GNTStatus%
     call SimoNOTE "ABENDING JobStep zBmsGeneration01, Status is %Compile2GNTStatus%, Program is %1"
     echo %1>%BaseLib1%\LOGS\%1.ERR
     goto :End
rem  *
rem  * ************************************************************************
:End

Advanced Functions, Compile Online COBOL Programs
(Next) (Previous) (Table-of-Contents)

The following is a listing of the command file (CompileGNTascForSam1Online) that does the multiple compilations of the COBOL programs for the online environment. This script will read a file that contains a list of COBOL source members that contain EXEC CICS statements and call the "zCompileToGnts01.CMD" to do the actual generation for each source member in the list.

@echo OFF
rem  * ************************************************************************
rem  * This procedure calls the following Windows Command Files.
rem  * 1. Env1Base.CMD - this provides a single point for setting commonly
rem  *    used environment variables.
rem  * 2. SimoNOTE.CMD - this provides a consistent process for displaying
rem  *    messages to the screen and writing to a journal or log file.
rem  * 3. zCompileToGnts01.CMD - this will do the actual compile of the
rem  *    specified program.
rem  * ************************************************************************
     setlocal
     call ..\Env1Base
     set CmdName=CompileGNTascForSam1Online
rem  *
     call SimoNOTE "****************************************%CmdName%.CMD"
     call SimoNOTE "Starting JobName %CmdName%.CMD"
rem  *
rem  * Set the environment variable to use the Active01.DIR directives file
rem  * as the default.
     set zDIRS=%BaseLib1%\DIRS\OS390AscOnline.DIR
rem  * The following two statements will set the environment variables to
rem  * a "Y" for Yes or "N" for No. A "Y" will cause the function to be
rem  * performed by the called procedure. An "N" value will not perform the
rem  * function.
     set EraseAfter=N
     set TransferGNT=N
rem  *
rem  * Read the ListSam1CblOnline file and pass the contents of each record to the
rem  * command file that does the actual compile. Each record in the file
rem  * contains an eight character program name. The following parameters are
rem  * passed to the called command file.
rem  * Parameter  Description
rem  * ---------  ------------------------------------------------------------
rem  *    1       Name of source member
rem  *    2       Name of source directory relative to BaseLib1
rem  *    3       Name of directory for load member relative to BaseLib1
rem  *
     for /F %%i in (ListSam1CblOnline.TXT) do CALL zCompileToGNTs01 %%i COBOLcs1 StagLibA
rem  *
     call SimoNOTE "Finished JobName %CmdName%.CMD"
     if not "%SimoGENS%" == "BATCH" pause
     endlocal

Advanced Functions, Generate non-Executable Load Members
(Next) (Previous) (Table-of-Contents)

The following is a listing of the command file that does a generation of the non-executable load members for the online environment.

Many online applications use data tables. These tables are usually defined in a COBOL copy file that is part of Working Storage. If the table changed the copy file was changed and all programs that used the copy file were re-compiled. If a table required frequent changes and was used by a number of different programs the use of the copy file became problematic. To solve this problem tables were coded as separate members and loaded at execution time using the EXEC CICS LOAD command. In order to create a non-executable load member the tables were coded in Mainframe Assembler using the DC (or Define Constant) statement.

This approach works quite well in the mainframe, EBCDIC-encoded environment were the Assembler Compiler is readily available. Also, this works quite well when moving the application to a Windows platform using Micro Focus Mainframe Express that provides support for EBCDIC encoding and a mainframe assembler capability.

The problem arises when the application is moved to a Windows or UNIX platform with Micro Focus Enterprise Server configured for an ASCII-encoded environment. To do this requires a special program that is capable of reading and parsing the DC statements in a mainframe assembler source member and creating an ASCII-encoding, non-executable load members. This program is available and described in a separate document.

The following is a list of the command file (GenerateMODascForSam1Online.CMD) that does the multiple generations of non-executable load members for the online environment. This script will read a file that contains a list of assembler source members and call the "zModGeneration01.CMD" to do the actual generation for each source member in the list.

@echo OFF
rem  * ************************************************************************
rem  * This procedure calls the following Windows Command Files.
rem  * 1. Env1Base.CMD - this provides a single point for setting commonly
rem  *    used environment variables.
rem  * 2. SimoNOTE.CMD - this provides a consistent process for displaying
rem  *    messages to the screen and writing to a journal or log file.
rem  * 3. zModGeneration01.CMD - this will do the actual geberation of the
rem  *    specified member.
rem  * ************************************************************************
     setlocal
     call ..\Env1Base
     set CmdName=GenrateMODascForSam1Online
rem  *
     call SimoNOTE "****************************************%CmdName%.CMD"
     call SimoNOTE "Starting JobName %CmdName%.CMD"
     set ASMOFORM=ASC
rem  *
rem  * Read the ListSam1ModOnline.txt file and pass the contents of each
rem  * record to the command file that does the actual generation. Each
rem  * record in the file contains an eight character member name.
     for /F %%i in (ListSam1ModOnline.txt) do CALL zModGeneration01 %%i ASM StagLibA LIST
rem  *
     call SimoNOTE "Finished JobName %CmdName%.CMD"
     if not "%SimoGENS%" == "BATCH" pause
     endlocal

The following is the command file (zModGeneration01.CMD) that does a single MOD generation from a single Assembler source member. This command file is usually called from the "GenerateMODascForSam1Online.CMD" command file.

@echo OFF
     echo Parameter 1 is %1
     echo CobCpy is %CobCpy%
     set CreateMODStatus=0000
rem  *
rem  * It is the callers reponsibility to set BaseLib1 to the base
rem  * directory. This procedure uses various sub-directories under the
rem  * base directory.
rem  *
rem  * The following parameters are received from the calling command file.
rem  * Parameter  Description
rem  * ---------  ------------------------------------------------------------
rem  *    1       Name of source member
rem  *    2       Name of source directory relative to BaseLib1
rem  *    3       Name of directory for load member relative to BaseLib1
rem  *    4       Name of directory for list member relative to BaseLib1
rem  *
rem  * ************************************************************************
     call SimoNOTE "Starting JobStep zModGeneration01, Status is %CreateMODStatus%, Program is %1"
rem  *
rem  * ************************************************************************
rem  * Do the build to create the .MOD non-executable using a COBOL program
     set ASMOTAKE=%BaseLib1%\%2\%1.MLC
     set ASMOMAKE=%BaseLib1%\%3\%1.MOD
     set ASMOLIST=%BaseLib1%\%4\%1.LST
     run ASMOGENR
     echo ErrorLevel is %ERRORLEVEL%
     if not "%ERRORLEVEL%" == "0" set CreateMODStatus=0010
     if not "%CreateMODStatus%" == "0000" goto :CreateMODNOK
rem  *
     echo %ASMOMAKE%
     if exist %ASMOMAKE% goto :CreateMODAOK
     set CreateMODStatus=0020
     goto :CreateMODNOK
rem  *
rem  * ************************************************************************
:CreateMODAOK
     call SimoNOTE "Complete JobStep zModGeneration01, Status is %CreateMODStatus%, Program is %1"
     goto :End
rem  *
rem  * ************************************************************************
:CreateMODNOK
     set JobStatus=%Compile2GNTStatus%
     call SimoNOTE "ABENDING JobStep zModGeneration01, Status is %CreateMODStatus%, Program is %1"
     echo %1>%BaseLib1%\LOGS\%1.ERR
     goto :End
rem  *
rem  * ************************************************************************
:End
     exit /B %CreateMODStatus%

Advanced Functions, the Directory Structure
(Next) (Previous) (Table-of-Contents)

The subdirectories under the primary (or base) directory (SimoSam1) are as follows.

The preceding is provided for reference purposes and may be modified to meet specific requirements or naming conventions. Additional sub-directories that address requirements beyond the scope of the scripted build process may be in the base directory. The use of additional sub-directories is described in documents that address additional requirements and functionality.

Special Handling
(Next) (Previous) (Table-of-Contents)

This section provides additional detail about application build process.

Special Handling, Compiler Directives
(Next) (Previous) (Table-of-Contents)

Compiler directives may be individually specified in the source code of a COBOL program, as part of a Net Express project or grouped together in a directives file that may be referenced by the project or command that is doing the compile. This suite of examples uses directives files, one for the batch environment and one for the online environment.

Note: the NOFORM directive must follow the LIST() directive. The LIST directive will set FORM"60".

Note: the NOFORM directive must follow the LIST() directive. The LIST directive will set FORM"60".

When the NOFORM directive is used the listing will be created without print carriage control and page headers. This makes for easier viewing from the screen and produces a listing file with the included copy files. This listing file could be renamed with a .CBL extension and compiled.

Special Handling, Compile a Single COBOL Program
(Next) (Previous) (Table-of-Contents)

The following is the command file (zCompileToGnts01.CMD) that does a single compile from a single COBOL source member. This command file is usually called from the "CompileGNTascForSam1Batch.CMD" command file for batch programs and the "CompileGNTascForSam1Online.CMD" command file for online programs.

     echo Parameter 1 is %1
     echo CobCpy is %CobCpy%
     set Compile2GNTStatus=0000
rem  *
rem  * It is the callers reponsibility to set BaseLib1 to the base
rem  * directory. This procedure uses various sub-directories under the
rem  * base directory.
rem  *
rem  * The following parameters are received from the calling command file.
rem  * Parameter  Description
rem  * ---------  ------------------------------------------------------------
rem  *    1       Name of source member
rem  *    2       Name of source directory relative to BaseLib1
rem  *    3       Name of directory for load member relative to BaseLib1
rem  *
rem  * ************************************************************************
rem  * The following two statements will first set the compile options to use
rem  * the directives file specified in the zDIRS environment variable. The
rem  * second statement will then check for a .DIR file with the same name as
rem  * the program. If this exists then it will override zDIRS value.
     set CompileOptions=%zDIRS%
     if exist %BaseLib1%\DIRS\%~n1.DIR set CompileOptions=%BaseLib1%\DIRS\%~n1.DIR
     call SimoNOTE "Starting zCompileToGnts01, Status is %Compile2GNTStatus%, Program is %1"
     echo Compile Options = %CompileOptions%
     call SimoNOTE "InfoNote %CompileOptions%"
rem  *
rem  * ************************************************************************
rem  * Do the compile to create the .GNT executable using Micro Focus compiler.
     cobol %BaseLib1%\%2\%1 OMF(GNT),%BaseLib1%\%3\ USE(%CompileOptions%) LISTPATH(%BaseLib1%\LIST);
     if not "%ERRORLEVEL%" == "0" set Compile2GNTStatus=0010
     if not "%Compile2GNTStatus%" == "0000" goto :Compile2GNTNOK
rem  *
     echo %BaseLib1%\%3\%1.GNT
     if exist %BaseLib1%\%3\%1.GNT goto :Compile2GNTAOK
     set Compile2GNTStatus=0020
     goto :Compile2GNTNOK
rem  *
rem  * ************************************************************************
:Compile2GNTAOK
     if "%TransferGnt%"=="Y"  (echo Transfer GNT is ENABLED
                               COPY /Y %BaseLib1%\%3\%1.GNT %BaseLib1%\ProdLib1\%1.GNT)
     if "%EraseAfter%"=="Y"   (echo Erase After is ENABLED
                               ERASE %BaseLib1%\%3\%1.GNT)
     call SimoNOTE "Complete zCompileToGnts01, Status is %Compile2GNTStatus%, Program is %1"
     goto :End
rem  *
rem  * ************************************************************************
:Compile2GNTNOK
     set JobStatus=%Compile2GNTStatus%
     call SimoNOTE "ABENDING zCompileToGnts01, Status is %Compile2GNTStatus%, Program is %1"
     echo %1 - Error during Compile, refer to %BaseLib1%\LIST\%1.LST>%BaseLib1%\LOGS\%1.ERR
     goto :End
rem  *
rem  * ************************************************************************
:End

Special Handling, Setting the Environment
(Next) (Previous) (Table-of-Contents)

A command file (Env1BASE.CMD located in the base directory named SimoSam1) is called from other command files to set commonly used environment variables. This provides a single point of definition. The following is a listing of the contents of the command file.

@echo off
rem  * *******************************************************************
rem  *                   This program is provided by:                    *
rem  *                    SimoTime Enterprises, LLC                      *
rem  *           (C) Copyright 1987-2010 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Provide a single point to set commonly used environment variables.
rem  * Author - SimoTime Enterprises
rem  * Date   - January 24, 1996
rem  *
rem  * Set the commonly used environment variables. This is used to provide
rem  * a single point for managing the commonly used environment variables.
rem  *
     set BaseLib1=c:\SimoAdm1
     set syslog=%BaseLib1%\LOGS\SysLog01.TXT
     set SimoNOTE=%BaseLib1%\LOGS\SysLog01.TXT
     call SimoNOTE "Starting JobName Env1Devl.CMD"
     set sysout=%BaseLib1%\LOGS\SYSOUTT1.TXT
rem  *
     set path="C:\Program Files\Micro Focus\Net Express\Base\";"C:\Program Files\Micro Focus\Net Express\Base\bin";%PATH%
rem  *
     set JobStatus=0000
     call SimoNOTE "Finished JobName Env1Devl.CMD"

Special Handling, Displaying and Logging Messages
(Next) (Previous) (Table-of-Contents)

The following is a listing of the contents of the (SimoNOTE.CMD) command file.

@echo OFF
rem  * *******************************************************************
rem  *                   This program is provided by:                    *
rem  *                    SimoTime Enterprises, LLC                      *
rem  *           (C) Copyright 1987-2010 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text    - Display message on screen and write to a log file.
rem  * Author  - SimoTime Enterprises
rem  *
rem  * This script may be called from other scripts and expects a
rem  * single parameter enclosed in double quotes. The double quotes
rem  * will be removed. Before writing to the log file a date and time
rem  * stamp will be inserted in front of the message text.
rem  *
rem  * Note: The tilde (~) removes leading/trailing double-quotes.
rem  *
if "%SimoNOTE%" == "" set SimoNOTE=c:\SimoLIBR\LOGS\SimoTime.LOG
echo %date% %time% %~1>> %SimoNOTE%
echo %~1

Possibilities & Considerations
(Next) (Previous) (Table-of-Contents)

This section provides information that addresses specific items pertaining to the function and capabilities and their potential use within or beyond the author's original design objectives.

Frequently Asked Questions (FAQ's)
(Next) (Previous) (Table-of-Contents)

This section is a list of frequently asked questions preceded by a date stamp.

Summary
(Next) (Previous) (Table-of-Contents)

The purpose of this program is to provide a model suite of Windows Command Files to do a scripted build of an application that has been migrated from a Mainframe System to a Windows System using Micro Focus Enterprise Server or Mainframe Express..

Software Agreement and Disclaimer
(Next) (Previous) (Table-of-Contents)

Permission to use, copy, modify and distribute this software for any commercial purpose requires a fee to be paid to SimoTime Enterprises. Once the fee is received by SimoTime the latest version of the software will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Enterprises.

Permission to use, copy, modify and distribute this software for a non-commercial purpose and without fee is hereby granted, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Enterprises.

SimoTime Enterprises makes no warranty or representations about the suitability of the software for any purpose. It is provided "AS IS" without any express or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Enterprises shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software.

Downloads and Links to Similar Pages
(Next) (Previous) (Table-of-Contents)

You may download this example at http://www.simotime.com/sim4dzip.htm#bdscript or view the complete list of SimoTime Examples at http://www.simotime.com/sim4dzip.htm.

Note: You must be attached to the Internet to download a Z-Pack or view the list.

To review all the information available on this site start at  The SimoTime Home Page .

Glossary of Terms
(Next) (Previous) (Table-of-Contents)

Check out  The SimoTime Glossary  for a list of terms and definitions used in the documents provided by SimoTime.

Comments or Suggestions
(Next) (Previous) (Table-of-Contents)

If you have any questions, suggestions or comments please call or send an e-mail to: helpdesk@simotime.com

We appreciate your comments and feedback.

About SimoTime Enterprises
(Next) (Previous) (Table-of-Contents)

Founded in 1987, SimoTime Enterprises is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. This includes the smallest thin client using the Internet and the very large mainframe systems. There is more to making the Internet work for your company's business than just having a nice looking WEB site. It is about combining the latest technologies and existing technologies with practical business experience. It's about the business of doing business and looking good in the process. Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complimentary manner with existing corporate mainframe systems. Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com