Repository Inquiry & Update using CICS
|
Application Properties Repository Inquiry & Update using CICS |
|
| The SimoTime Home Page |
Introduction
This example uses a suite of COBOL programs and BMS map sets to display a screen that will prompt a user for a source member name. Once a source member name is entered the program will access the Application Properties Repository (APMASTER is a VSAM, KSDS). The programs use command level CICS statements to access APMASTER and display information to a 3270 terminal or terminal emulator. The programs run on an IBM Mainframe System with CICS or a Microsoft Windows System with Micro Focus Server.
The Application Properties Repository (or APMASTER) may be viewed and/or updated by submitting a transaction directly to CICS or via a Menu Option provided with the CICS Sample Programs.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved
The CICS Transaction (APU1)
Start a 3270 Session and execute the "APU1" Transaction. The following is an overview of the processing logic.
|
AP2UPD1 Application Inventory of Program Members 2009/08/04
STOA Source Code Repository - Update Option 17:44:00:14
Enter Next SCDB ID: CBLJUSC1.CBL 00
SCDB ID: CBLJUSC1.CBL 00
Language Member Type
Used: CBL CBL
User Override: UNKNOWN UNKNOWN
SimoLYZE Scan: CBL CBL
Records Comments Blank Lines Lines of Code
447 135 20 292
Last Activity Date: 20090706 Time: 22490106 Status: A
F3=Menu F9=Updt F12=Esc |
Note: The SCDB ID (or Source Code Data Base Identifier) is a twelve (12) character data string that is the filename.ext. This is the eight character member name and the three character extension delimited by a period or full stop character.
The COBOL Program
The following (AP2UPD) is the COBOL Source Code that is used to access the Application Properties Repository (APMASTER).
IDENTIFICATION DIVISION.
PROGRAM-ID. AP2UPD.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
* MAINTENANCE
* -----------
* 1989/02/27 Simmons, Created program.
* 1997/03/17 Simmons, Updated for SYSID.
*
*****************************************************************
*
ENVIRONMENT DIVISION.
*****************************************************************
DATA DIVISION.
WORKING-STORAGE SECTION.
01 VERSION-NUMBER pic X(9) value 'V01.00.00'.
01 PF-ROW-23.
05 filler pic X(3) value SPACES.
05 PF-ROW-23-04 pic X(8) value SPACES.
05 PF-ROW-23-12 pic X(8) value SPACES.
05 PF-ROW-23-20 pic X(8) value 'F3=Menu '.
05 PF-ROW-23-28 pic X(8) value SPACES.
05 PF-ROW-23-36 pic X(8) value SPACES.
05 PF-ROW-23-44 pic X(8) value SPACES.
05 PF-ROW-23-52 pic X(8) value SPACES.
05 PF-ROW-23-60 pic X(8) value SPACES.
05 PF-ROW-23-68 pic X(8) value 'F12=Esc '.
05 filler pic X(3) value SPACES.
01 EOJ-MESSAGE pic X(50)
value ' - Enter Tran ID . . . completed AP2UPD'.
01 RECORD-LENGTH-1024 pic S9(4) comp value 1024.
01 DATA-RESP-CODE pic 9(08) comp.
01 XCTL-RESP-CODE pic 9(08) comp.
01 NUMBER-WORK-16 pic 9(16) value 0.
01 X-EIB-MESSAGE.
05 filler pic X(8) value 'EIBRESP='.
05 X-EIB-RESP pic 9(10) value 0.
05 filler pic X(11) value ', EIBRESP2='.
05 X-EIB-RESP2 pic 9(10) value 0.
05 filler pic X value SPACE.
05 X-EIB-USER-MSG pic X(38) value SPACES.
01 APMASTER-READ-KEY pic X(18).
01 MSG-LINE-1 pic X(78) value LOW-VALUES.
01 MSG-LINE-2 pic X(78) value LOW-VALUES.
01 SYS-ID pic X(4).
01 WORK-DATE.
05 WORK-DATE-CC pic X(02).
05 WORK-DATE-YY pic 9(02).
05 WORK-DATE-MM pic X(02).
05 WORK-DATE-DD pic 9(02).
01 WORK-TIME.
05 WORK-TIME-HH pic X(02).
05 WORK-TIME-NN pic X(02).
05 WORK-TIME-SS pic X(02).
05 WORK-TIME-TT pic X(02).
01 EDITED-09 pic ZZZ,ZZZ,ZZ9.
01 Z-WORK-12 pic X(12) value SPACES.
01 IX-12 pic 9(3) value 0.
01 PROGRAM-NAME pic x(8) value SPACES.
01 WS-RESPONSE pic S9(8) comp.
01 WS-REASON-CODE pic S9(8) comp.
01 LOCAL-TRAN-ID pic X(4) value 'APU1'.
01 PROGRAM-FLAGS.
05 P-FLAG-ANIM pic X value 'N'.
05 P-FLAG-JOURNAL pic X value 'Y'.
01 WORK-ITEMS.
05 WS-ESD128-RIDFLD PIC S9(8) COMP VALUE +0.
05 WS-ESD01K-RIDFLD PIC S9(8) COMP VALUE +0.
05 WS-ESD350-RIDFLD PIC S9(8) COMP VALUE +0.
01 ESD128-RECORD.
05 ESD128-DATA pic X(128) value SPACES.
01 ESD128-FILE pic X(8) value 'ESDSC128'.
01 ESD01K-RECORD.
05 ESD01K-DATA pic X(128) value SPACES.
01 ESD01K-FILE pic X(8) value 'ESDSC01K'.
01 ESD350-RECORD.
05 ESD350-DATA pic X(350) value SPACES.
01 ESD350-FILE pic X(8) value 'ESDSC350'.
COPY AP2UPD1.
COPY DFHBMSCA.
COPY DFHAID.
* COPY DFHEIBLK.
COPY APMASTB1.
*****************************************************************
LINKAGE SECTION.
01 DFHCOMMAREA.
03 LS-SLZKEY pic X(18).
03 filler pic X(4096).
*****************************************************************
PROCEDURE DIVISION.
* if P-FLAG-ANIM = 'Y'
* CALL 'CBL_DEBUGBREAK'
* end-if.
perform CLEAR-MESSAGES
EXEC CICS HANDLE CONDITION
ERROR (GENERAL-ERROR-ROUTINE)
MAPFAIL (MAP-FAIL-ROUTINE)
NOTFND (GENERAL-ERROR-ROUTINE)
END-EXEC.
evaluate TRUE
when EIBCALEN = ZERO
perform SCREEN-IO-SEND-UPDATE
when EIBAID = DFHPF3
perform END-OF-PROGRAM-03
when EIBAID = DFHPF9
perform UPDATE-CUSTOMER-INFORMATION
when EIBAID = DFHPF12
perform END-OF-PROGRAM-12
when EIBAID = DFHENTER
perform GET-CUSTOMER-INFORMATION
when other
move 'Type a new request and press the ENTER key'
to MSG-LINE-1
perform RECOVERY-ROUTINE
end-evaluate.
* Should never get to here...
perform END-OF-PROGRAM-12.
*****************************************************************
BUILD-HEADER-INFO.
EXEC CICS ASSIGN
SYSID(SYS-ID)
END-EXEC.
move 'AP2UPD1 ' to SYSPAGEO
move SYS-ID to SYS-IDO.
perform Z-GET-DATE-AND-TIME.
exit.
*****************************************************************
APMASTER-READ.
move LS-SLZKEY to APMASTER-READ-KEY.
EXEC CICS READ
DATASET ('APMASTER')
INTO (APMASTER-RECORD)
LENGTH (RECORD-LENGTH-1024)
RIDFLD (APMASTER-READ-KEY)
KEYLENGTH (18)
RESP (DATA-RESP-CODE)
END-EXEC.
exit.
*****************************************************************
APMASTER-READ-UPDATE.
EXEC CICS READ
DATASET ('APMASTER')
INTO (APMASTER-RECORD)
LENGTH (RECORD-LENGTH-1024)
RIDFLD (APMASTER-READ-KEY)
KEYLENGTH (18)
UPDATE
RESP (DATA-RESP-CODE)
END-EXEC.
exit.
*****************************************************************
APMASTER-REWRITE.
EXEC CICS REWRITE
DATASET ('APMASTER')
FROM (APMASTER-RECORD)
LENGTH (RECORD-LENGTH-1024)
RESP (DATA-RESP-CODE)
END-EXEC.
exit.
*****************************************************************
CLEAR-MESSAGES.
move SPACES to MSG-LINE-1
move SPACES to MSG-LINE-2
move SPACES to SYSMSG1O
move SPACES to SYSMSG2O
exit.
*****************************************************************
DATA-FILE-TO-SCREEN.
move APMASTER-KEY to NEWKEYO
move APMASTER-KEY to SLZKEYO
move APMASTER-LANGUAGE to SLZLAN1O
move APMASTER-LANGUAGE-USER to SLZLAN2O
move APMASTER-LANGUAGE-MFA to SLZLAN3O
move APMASTER-TYPE to SLZTYP1O
move APMASTER-TYPE-USER to SLZTYP2O
move APMASTER-TYPE-MFA to SLZTYP3O
add APMASTER-RECORDS to ZERO giving EDITED-09
move EDITED-09 to SLZRECSO
add APMASTER-COMMENTS to ZERO giving EDITED-09
move EDITED-09 to SLZCMTSO
add APMASTER-BLANK-LINES to ZERO giving EDITED-09
move EDITED-09 to SLZBLKSO
add APMASTER-LINES-OF-CODE to ZERO giving EDITED-09
move EDITED-09 to SLZLOCSO
move APMASTER-LAST-ACTIVITY-DATE to SLZLDATO
move APMASTER-LAST-ACTIVITY-TIME to SLZLTIMO
move APMASTER-RECORD-STATUS to SLZSTATO
exit.
*****************************************************************
DATA-INITIALIZE-SCREEN-RECORD.
move SPACES to NEWKEYO
SLZKEYO
SLZLAN1O
SLZLAN2O
SLZLAN3O
SLZTYP1O
SLZTYP2O
SLZTYP3O
SLZRECSO
SLZCMTSO
SLZBLKSO
SLZLOCSO
SLZLDATO
SLZLTIMO
SLZSTATO
SYSMSG1O
SYSMSG2O
exit.
*****************************************************************
DATA-SCREEN-TO-FILE.
* move NEWKEYI to APMASTER-KEY
move SLZKEYI to APMASTER-KEY
move SLZLAN2O to APMASTER-LANGUAGE-USER
move SLZTYP2O to APMASTER-TYPE-USER
move SLZLDATI to APMASTER-LAST-ACTIVITY-DATE
move SLZLTIMI to APMASTER-LAST-ACTIVITY-TIME
move SLZSTATI to APMASTER-RECORD-STATUS
exit.
*****************************************************************
END-OF-PROGRAM-03.
move 'MN1UTL ' to PROGRAM-NAME
perform TRANSFER-CONTROL
* Should never get to here...
exit.
*****************************************************************
END-OF-PROGRAM-12.
EXEC CICS SEND
FROM (EOJ-MESSAGE)
LENGTH (50)
ERASE
END-EXEC
EXEC CICS SEND
CONTROL FREEKB
END-EXEC
EXEC CICS RETURN
END-EXEC
exit.
*****************************************************************
GENERAL-ERROR-ROUTINE.
move ' General Error'
to X-EIB-USER-MSG
add EIBRESP to ZERO giving X-EIB-RESP
add EIBRESP2 to ZERO giving X-EIB-RESP2
move X-EIB-MESSAGE to MSG-LINE-2.
perform RECOVERY-ROUTINE
* Should never get to here...
exit.
*****************************************************************
GET-CUSTOMER-INFORMATION.
perform SCREEN-IO-GET-DATA-FOR-INQUIRY
perform APMASTER-READ
if DATA-RESP-CODE = ZEROS
move 'F9=Updt ' to PF-ROW-23-44
perform DATA-FILE-TO-SCREEN
else
perform DATA-INITIALIZE-SCREEN-RECORD
move LS-SLZKEY to MSG-LINE-1
move '* Member record not found,please try again...'
to MSG-LINE-1(20:48)
perform POST-MSG-2-EIBRESP
perform RECOVERY-ROUTINE
end-if.
perform SCREEN-IO-SEND-UPDATE
* Should never get to here...
exit.
*****************************************************************
MAP-FAIL-ROUTINE.
move ' Map Failure'
to X-EIB-USER-MSG
add EIBRESP to ZERO giving X-EIB-RESP
add EIBRESP2 to ZERO giving X-EIB-RESP2
move X-EIB-MESSAGE to MSG-LINE-2.
perform RECOVERY-ROUTINE
* Should never get to here...
exit.
*****************************************************************
POST-MSG-2-EIBRESP.
if X-EIB-USER-MSG = SPACES
move ' EIB Response'
to X-EIB-USER-MSG
end-if
add EIBRESP to ZERO giving X-EIB-RESP
add EIBRESP2 to ZERO giving X-EIB-RESP2
move X-EIB-MESSAGE to MSG-LINE-2.
exit.
*****************************************************************
RECOVERY-ROUTINE.
move MSG-LINE-1 to SYSMSG1O.
move MSG-LINE-2 to SYSMSG2O.
move -1 to NEWKEYL
perform SCREEN-IO-SEND-UPDATE
* Should never get to here...
exit.
*****************************************************************
SCREEN-IO-GET-DATA-FOR-INQUIRY.
EXEC CICS RECEIVE
MAP ('AP2UPD1')
MAPSET ('AP2UPD1')
RESP(WS-RESPONSE)
RESP2(WS-REASON-CODE)
END-EXEC.
if NEWKEYL > ZERO
* move NEWKEYI to Z-WORK-12
* perform Z-RIGHT-ADJUST-Z-WORK-12
* move Z-WORK-12 to NEWKEYI
move NEWKEYI to LS-SLZKEY
move '00' to LS-SLZKEY(17:2)
else
move 'Please enter a 12 digit customer number...'
to MSG-LINE-1
perform RECOVERY-ROUTINE
end-if.
exit.
*****************************************************************
SCREEN-IO-GET-DATA-FOR-UPDATE.
EXEC CICS RECEIVE
MAP ('AP2UPD1')
MAPSET ('AP2UPD1')
END-EXEC.
if NEWKEYL > ZERO
move NEWKEYI to Z-WORK-12
perform Z-RIGHT-ADJUST-Z-WORK-12
move Z-WORK-12 to NEWKEYI
move NEWKEYI to LS-SLZKEY
end-if.
exit.
*****************************************************************
SCREEN-IO-SEND-UPDATE.
perform BUILD-HEADER-INFO
move PF-ROW-23 to PFROW23O
EXEC CICS SEND
MAP ('AP2UPD1')
MAPSET ('AP2UPD1')
ERASE
END-EXEC
move LOW-VALUES to AP2UPD1O
EXEC CICS RETURN
TRANSID (LOCAL-TRAN-ID)
COMMAREA (AP2UPD1O)
LENGTH (4096)
END-EXEC
* Should never get to here...
exit.
*****************************************************************
TRANSFER-CONTROL.
EXEC CICS XCTL
PROGRAM(PROGRAM-NAME)
RESP(XCTL-RESP-CODE)
END-EXEC
* Should never get to here...
move 'Program not found, &&&&&&&&' to MSG-LINE-1.
inspect MSG-LINE-1 replacing first '&&&&&&&&'
by PROGRAM-NAME
move -1 to NEWKEYL.
perform RECOVERY-ROUTINE.
* exit.
*****************************************************************
UPDATE-CUSTOMER-INFORMATION.
perform SCREEN-IO-GET-DATA-FOR-UPDATE
move SLZKEYI to APMASTER-READ-KEY
perform APMASTER-READ-UPDATE
if DATA-RESP-CODE not = 0
add DATA-RESP-CODE to ZERO giving NUMBER-WORK-16
move 'ReRead Failed, ' to MSG-LINE-1(1:16)
move SLZKEYI to MSG-LINE-1(16:12)
move APMASTER-KEY to MSG-LINE-1(30:12)
move VERSION-NUMBER to MSG-LINE-1(70:9)
perform GENERAL-ERROR-ROUTINE
end-if.
perform DATA-SCREEN-TO-FILE
perform Z-GET-DATE-AND-TIME
move WORK-DATE to APMASTER-LAST-ACTIVITY-DATE
move WORK-TIME to APMASTER-LAST-ACTIVITY-TIME
move ZEROES to APMASTER-RECORD-STATUS
perform APMASTER-REWRITE
if DATA-RESP-CODE = 0
move
'Update Completed, type new request and press ENTER key'
to MSG-LINE-1(1:54)
move MSG-LINE-1 to SYSMSG1O
move ' ' to PF-ROW-23-44
perform SCREEN-IO-SEND-UPDATE
else
add DATA-RESP-CODE to ZERO giving NUMBER-WORK-16
move 'Update Failed, ' to MSG-LINE-1(1:16)
move SLZKEYI to MSG-LINE-1(16:12)
move APMASTER-KEY to MSG-LINE-1(30:12)
move VERSION-NUMBER to MSG-LINE-1(70:9)
perform GENERAL-ERROR-ROUTINE
end-if.
* Should never get to here...
exit.
*****************************************************************
* Delete all characters to the right of the first space then
* right-adjust with zero fill. This routine works with a single,
* twelve character field and does not require a work area.
*****************************************************************
Z-RIGHT-ADJUST-Z-WORK-12.
inspect Z-WORK-12
replacing CHARACTERS by ' ' after initial ' '
perform until Z-WORK-12(12:1) not = SPACE
if Z-WORK-12(12:1) = SPACE
add 11 to ZERO giving IX-12
perform 11 times
move Z-WORK-12(IX-12:1) to Z-WORK-12(IX-12 + 1:1)
subtract 1 from IX-12
end-perform
move ZERO to Z-WORK-12(1:1)
end-if
end-perform
exit.
*****************************************************************
Z-GET-DATE-AND-TIME.
accept WORK-DATE from DATE YYYYMMDD
accept WORK-TIME from TIME
move 'ccyy/mm/dd' to SYSDATEO
move WORK-DATE(1:4) to SYSDATEO(1:4)
move WORK-DATE(5:2) to SYSDATEO(6:2)
move WORK-DATE(7:2) to SYSDATEO(9:2)
move 'hh:mm:ss:dd' to SYSTIMEO
move WORK-TIME(1:2) to SYSTIMEO(1:2)
move WORK-TIME(3:2) to SYSTIMEO(4:2)
move WORK-TIME(5:2) to SYSTIMEO(7:2)
move WORK-TIME(7:2) to SYSTIMEO(10:2)
exit.
Application Properties Repository
The Application Properties Repository is a VSAM, Key Sequenced Data Structure (or KSDS). It has a record length of 1,024 bytes with a 18 byte key starting in position 1 of the record. The following copy file (APMASTB1.cpy) shows the record structure.
*****************************************************************
* APMASTB1 is a COBOL Copy File *
* Copy File for SIMOLYZE Application Properties Repository *
* This is a VSAM Keyed Sequence Data Structure (KSDS) *
* or a Micro Focus Keyed-Index File. *
* Copyright (C) 1987-2023 SimoTime Technologies *
* All Rights Reserved *
*****************************************************************
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
01 APMASTER-RECORD.
05 APMASTER-KEY.
10 APMASTER-KEY-16 PIC X(16).
10 APMASTER-RECORD-ID PIC 9(2).
05 APMASTER-DATA.
10 APMASTER-RECORD-STATUS PIC X.
10 APMASTER-LAST-ACTIVITY-DATE PIC X(8).
10 APMASTER-LAST-ACTIVITY-TIME PIC X(8).
10 APMASTER-MEMBER-DATE PIC X(8).
10 APMASTER-MEMBER-TIME PIC X(8).
10 APMASTER-LANGUAGE PIC X(8).
10 APMASTER-LANGUAGE-USER PIC X(8).
10 APMASTER-LANGUAGE-MFA PIC X(8).
10 APMASTER-TYPE PIC X(8).
10 APMASTER-TYPE-USER PIC X(8).
10 APMASTER-TYPE-MFA PIC X(8).
10 APMASTER-CICS PIC X.
10 APMASTER-CICS-USER PIC X.
10 APMASTER-CICS-MFA PIC X.
10 APMASTER-SQL PIC X.
10 APMASTER-SQL-USER PIC X.
10 APMASTER-SQL-MFA PIC X.
10 APMASTER-FLAGS.
15 APMASTER-FLAG-01 PIC X.
15 APMASTER-FLAG-02 PIC X.
15 APMASTER-FLAG-03 PIC X.
15 APMASTER-FLAG-04 PIC X.
15 APMASTER-FLAG-05 PIC X.
15 APMASTER-FLAG-06 PIC X.
15 APMASTER-FLAG-07 PIC X.
15 APMASTER-FLAG-08 PIC X.
10 APMASTER-FLAGS-USER.
15 APMASTER-FLAG-U1 PIC X.
15 APMASTER-FLAG-U2 PIC X.
15 APMASTER-FLAG-U3 PIC X.
15 APMASTER-FLAG-U4 PIC X.
15 APMASTER-FLAG-U5 PIC X.
15 APMASTER-FLAG-U6 PIC X.
15 APMASTER-FLAG-U7 PIC X.
15 APMASTER-FLAG-U8 PIC X.
10 APMASTER-RECORDS PIC 9(8).
10 APMASTER-BLANK-LINES PIC 9(8).
10 APMASTER-COMMENTS PIC 9(8).
10 APMASTER-LINES-OF-CODE PIC 9(8).
10 APMASTER-LA-DATE PIC X(8).
10 APMASTER-LA-TIME PIC X(8).
10 APMASTER-LA-TOKEN PIC 9(3).
10 APMASTER-DEPENDENCY-CODE PIC 9(5).
10 APMASTER-DEPENDENCY-EXEC PIC 9(5).
10 APMASTER-FILLER-00 PIC X(090).
10 APMASTER-MVS-MEMBER-NAME PIC X(016).
10 APMASTER-PCNAME PIC X(256).
10 APMASTER-MAKEACTION PIC X(224).
10 APMASTER-HOSTNAME PIC X(256).
*
*** APMASTB1 - End-of-Copy File - - - - - - - - - - - APMASTB1 *
*****************************************************************
*
Summary
The purpose of this suite of program is to provide examples that use command level CICS in COBOL programs to access VSAM, Key-Sequenced-Data-Sets (KSDS) and display the information using standard BMS screen definitions to a 3270 terminal or terminal emulator. Also, this document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the 
icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the 
icon.
Explore how to manage a repository of Application Assets that uses a VSAM, Key-Sequenced-Data-Set (a KSDS named APMASTER). The repository includes information about the program source members used for batch and transactional processing.
Explore how to load a Repository of Information about Application Assets that includes information about the source members. The repository is a VSAM, Key-Sequenced-Data-Set (a KSDS named APMASTER).
Explore the CICS Connection for more examples of mainframe CICS coding techniques and sample code.
Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available for download. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Contact or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| Application Properties, Repository Inquiry and Update using CICS |
| Copyright © 1987-2025 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |