EXEC CICS READQ TS for a Data Array
|
In Memory Table Access EXEC CICS READQ TS for a Data Array |
|
| The SimoTime Home Page |
Introduction
The transaction identifier (or TRANSID) is "DMPA" and the program is "DMPUA1". This option will do an EXEC CICS READQ TS of a Temporary Storage Queue that contains a list of addresses.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2024
SimoTime Technologies and Services
All Rights Reserved
Execute
This example may be executed by typing the TRANSID at the CICS startup screen or by selecting the menu option. The following message will be displayed on the screen, "Invoke, TABLE002 Loader Transaction". The message is displayed and the keyboard should be unlocked and ready for the next user request within a sub-second response time. The transaction will write multiple messages to the log file to display the execution of the program and the content of the loaded data table (i.e. non-Executable Load Member).
Log File Entries, Normal
The following shows the Log File entries for a normal completion of a program execution.
2014/12/18 - 10:11:32.81 - DMPUA1 - Program STARTING... 2014/12/18 - 10:11:32.81 - DMPUA1 - * 1-016 00000000 98F8DC7E 00000000 00000000 ....q8.=........ .......~........ 2014/12/18 - 10:11:32.81 - DMPUA1 - * 17-032 00000000 00000000 00000000 00000000 ................ ................ 2014/12/18 - 10:11:32.81 - DMPUA1 - * 33-048 00000000 00000000 00000000 00000000 ................ ................ 2014/12/18 - 10:11:32.81 - DMPUA1 - * 49-064 00000000 00000000 00000000 00000000 ................ ................ 2014/12/18 - 10:11:32.81 - DMPUA1 - * 65-080 00000000 00000000 00000000 00000000 ................ ................ 2014/12/18 - 10:11:32.81 - DMPUA1 - Program FINISHED...
Log File Entries, ABEND
The following shows the Log File entries for abnormal termination of a program execution.
2014/12/18 - 10:11:26.53 - DMPUA1 - Program STARTING... 2014/12/18 - 10:11:26.53 - DMPUA1 - EIBRESP=0000000044, EIBRESP2=0000000000 QIDERR Specified QUEUE cannot be found 2014/12/18 - 10:11:26.53 - DMPUA1 - Program ABENDING...
Technical Details
This section provides additional information about the ancillary tasks that are required to prepare the environment for executing the "Write-to-Log-File" transaction.
The Log File
The log file is a VSAM, Entry-Sequenced-Data-Set (ESDS). A batch job using the DELETE/DEFINE functions of IDCAMS is provided to create the VSAM, ESDS that will be used for logging user information.
Explore how to delete and define a new Entry Sequenced Data Set (ESDS) using Mainframe JCL. Once the new ESDS is created a COBOL program is used to add records to the data set.
The COBOL Program
The following is the COBOL program (DMPUA1.cbl) is the program that is used to get an address list from a Temporary Storage Queue. The address list contains addresses of memory-resident user tables.
IDENTIFICATION DIVISION.
PROGRAM-ID. DMPUA1.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
* MAINTENANCE
* -----------
* 1989/02/27 Simmons, Created program.
* 1997/03/17 Simmons, Updated for SYSID.
*
*****************************************************************
*
ENVIRONMENT DIVISION.
*****************************************************************
DATA DIVISION.
WORKING-STORAGE SECTION.
01 PF-ROW-23.
05 filler pic X(3) value SPACES.
05 PF-ROW-23-04 pic X(8) value SPACES.
05 PF-ROW-23-12 pic X(8) value SPACES.
05 PF-ROW-23-20 pic X(8) value 'F3=Menu '.
05 PF-ROW-23-28 pic X(8) value SPACES.
05 PF-ROW-23-36 pic X(8) value SPACES.
05 PF-ROW-23-44 pic X(8) value SPACES.
05 PF-ROW-23-52 pic X(8) value SPACES.
05 PF-ROW-23-60 pic X(8) value SPACES.
05 PF-ROW-23-68 pic X(8) value 'F12=Esc '.
05 filler pic X(3) value SPACES.
01 EOJ-MESSAGE pic X(50)
value ' - Enter Tran ID . . . completed DMPUA1'.
01 LGTH pic S9(4) comp.
01 WORK-RESP-CODE pic 9(08) comp.
01 ESDS-RESP-CODE pic 9(08) comp.
01 XCTL-RESP-CODE pic 9(08) comp.
01 NUMBER-WORK-16 pic 9(16) value 0.
01 MSG-LINES.
03 MSG-DATA pic X(78) value LOW-VALUES.
01 SYS-PAGE pic X(8) value 'DMPUA11 '.
01 SYS-ID pic X(4).
01 WORK-DATE-TIME.
05 WORK-DATE.
10 WORK-DATE-CC pic X(02).
10 WORK-DATE-YY pic 9(02).
10 WORK-DATE-MM pic X(02).
10 WORK-DATE-DD pic 9(02).
05 WORK-TIME.
10 WORK-TIME-HH pic X(02).
10 WORK-TIME-MM pic X(02).
10 WORK-TIME-SS pic X(02).
10 WORK-TIME-TT pic X(02).
01 LOG-MESSAGE.
05 EDIT-DATE-TIME.
10 EDIT-DATE.
15 EDIT-DATE-CC pic X(02).
15 EDIT-DATE-YY pic 9(02).
15 FILLER pic X value '/'.
15 EDIT-DATE-MM pic X(02).
15 FILLER pic X value '/'.
15 EDIT-DATE-DD pic 9(02).
10 FILLER pic X(3) value ' - '.
10 EDIT-TIME.
15 EDIT-TIME-HH pic X(02).
15 FILLER pic X value ':'.
15 EDIT-TIME-MM pic X(02).
15 FILLER pic X value ':'.
15 EDIT-TIME-SS pic X(02).
15 FILLER pic X value '.'.
15 EDIT-TIME-TT pic X(02).
10 FILLER pic X(3) value ' - '.
10 PROGRAM-NAME pic x(8) value 'DMPUA1 '.
10 FILLER pic X(3) value ' - '.
10 LOG-TEXT-GROUP.
15 LOG-TEXT pic X(50) value SPACES.
15 LOG-TEXT-EXT pic X(40) value SPACES.
01 X-EIB-MESSAGE.
05 filler pic X(8) value 'EIBRESP='.
05 X-EIB-RESP pic 9(10) value 0.
05 filler pic X(11) value ', EIBRESP2='.
05 X-EIB-RESP2 pic 9(10) value 0.
05 filler pic X value SPACE.
05 X-EIB-USER-MSG pic X(38) value SPACES.
01 W2-DATE PIC S9(7) COMP-3 value 0.
01 W2-TIME PIC S9(7) COMP-3 value 0.
01 WS-RESPONSE pic S9(8) comp.
01 WS-REASON-CODE pic S9(8) comp.
01 USER-ACTION-CODE pic X value SPACE.
01 LOCAL-TRAN-ID pic X(4) value 'DMPA'.
01 WORK-ITEMS.
05 WS-ESD128-RIDFLD PIC S9(8) COMP VALUE +0.
01 ESD128-RECORD.
05 ESD128-DATA pic X(128) value SPACES.
01 ESD128-FILE pic X(8) value 'ESDSC128'.
01 ADDRESS-LIST.
05 PTR-001 USAGE IS POINTER.
05 PTR-002 USAGE IS POINTER.
05 FILLER PIC X(72) VALUE IS LOW-VALUES.
01 ADDRESS-LIST-SIZE PIC 9(4) COMP VALUE 80.
01 TSQ-ITEM PIC 9(4) COMP VALUE 1.
01 IX-1 pic 9(5) value 0.
COPY PASSDUMP.
COPY DMPUA11.
COPY DFHBMSCA.
COPY DFHAID.
* COPY DFHEIBLK.
*****************************************************************
LINKAGE SECTION.
01 DFHCOMMAREA.
03 COMMAREA-128 pic X(128).
01 T002-BUFFER.
05 T002-SIZE PIC 9(4) COMP.
05 T002-COUNT PIC 9(4) COMP.
05 FILLER PIC X(2).
05 T002-ELEMENTS PIC X.
*****************************************************************
PROCEDURE DIVISION.
* if P-FLAG-ANIM = 'Y'
* CALL 'CBL_DEBUGBREAK'
* end-if.
perform Z-GET-DATE-AND-TIME
move 'Program STARTING...' to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
perform CLEAR-MESSAGES
perform ACTION-001
evaluate TRUE
when EIBCALEN = ZERO
* move SPACES to SYSMSG1O
move -1 to SYSMSG1L
perform SEND-PRIMARY-SCREEN
when EIBAID = DFHPF3
perform END-OF-PROGRAM-03
when EIBAID = DFHPF12
perform END-OF-PROGRAM-12
when EIBAID = DFHENTER
perform GET-ACTION-CODE
when other
move 'Please select a valid function/option number'
to MSG-LINES
perform RECOVERY-ROUTINE
end-evaluate.
* Should never get to here...
perform END-OF-PROGRAM-12.
*****************************************************************
ACTION-001.
perform Z-GET-DATE-AND-TIME
EXEC CICS READQ TS QUEUE('ADRLST')
ITEM(TSQ-ITEM)
INTO(ADDRESS-LIST)
LENGTH(ADDRESS-LIST-SIZE)
NOHANDLE
END-EXEC
if EIBRESP = 0
perform DUMP-ADRLST
move 'Request FINISHED...' to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
else
perform POST-EIB-ERROR
move X-EIB-MESSAGE to SYSMSG1O
move X-EIB-MESSAGE to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
move 'Request ABENDING...' to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
end-if
* EXEC CICS RETURN END-EXEC
exit.
*****************************************************************
BUILD-HEADER-INFO.
EXEC CICS ASSIGN
SYSID(SYS-ID)
END-EXEC.
move SYS-ID to SYS-IDO.
move SYS-PAGE to SYSPAGEO.
perform Z-GET-DATE-AND-TIME.
perform Z-GET-DATE-AND-TIME-CICS.
exit.
*****************************************************************
CLEAR-MESSAGES.
move SPACES to MSG-LINES
move SPACES to SYSMSG1O
exit.
*****************************************************************
DUMP-ADRLST.
add 80 to ZERO giving SIMODUMP-LENGTH
move 'NONE' to SIMODUMP-REQUEST
call 'SIMODUMP' using SIMODUMP-PASS-AREA ADDRESS-LIST
add 1 to ZERO giving IX-1
perform 5 times
move SIMODUMP-LINES(IX-1) to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
add 1 to IX-1
end-perform
move SIMODUMP-LINES(1) to LINE01O
move SIMODUMP-LINES(2) to LINE02O
move SIMODUMP-LINES(3) to LINE03O
move SIMODUMP-LINES(4) to LINE04O
move SIMODUMP-LINES(5) to LINE05O
exit.
*****************************************************************
END-OF-PROGRAM-03.
move 'Program FINISHED...' to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
move 'MN1ADV ' to PROGRAM-NAME
perform TRANSFER-CONTROL
* Should never get to here...
exit.
*****************************************************************
END-OF-PROGRAM-12.
EXEC CICS SEND
FROM (EOJ-MESSAGE)
LENGTH (50)
ERASE
END-EXEC
EXEC CICS SEND
CONTROL FREEKB
END-EXEC
EXEC CICS RETURN
END-EXEC
exit.
*****************************************************************
POST-EIB-ERROR.
if EIBRESP = 44
move 'QIDERR Specified QUEUE cannot be found'
to X-EIB-USER-MSG
else
move 'ERROR - a READQ TS of ADRLST failed '
to X-EIB-USER-MSG
end-if
add EIBRESP to ZERO giving X-EIB-RESP
add EIBRESP2 to ZERO giving X-EIB-RESP2
exit.
*****************************************************************
POST-TO-LOG-FILE-AND-CLEAR.
move LOG-MESSAGE to ESD128-RECORD
perform WRITE-TO-LOG
move SPACES to LOG-TEXT-GROUP
move SPACES to ESD128-RECORD
exit.
*****************************************************************
WRITE-TO-LOG.
EXEC CICS WRITE
FILE (ESD128-FILE)
FROM (ESD128-RECORD)
RIDFLD (WS-ESD128-RIDFLD)
RBA
LENGTH (LENGTH OF ESD128-RECORD)
RESP (ESDS-RESP-CODE)
END-EXEC
exit.
*****************************************************************
GET-ACTION-CODE.
EXEC CICS RECEIVE
MAP ('DMPUA11')
MAPSET ('DMPUA11')
RESP(WS-RESPONSE)
RESP2(WS-REASON-CODE)
END-EXEC.
move ACTCODEI to USER-ACTION-CODE
evaluate USER-ACTION-CODE
when '1' perform ACTION-001
perform SEND-PRIMARY-SCREEN
when other move 'Enter a valid Action Code' to SYSMSG1O
perform SEND-PRIMARY-SCREEN
end-evaluate
* Should never get to here...
exit.
*****************************************************************
RECOVERY-ROUTINE.
move MSG-LINES to SYSMSG1O.
move -1 to SYSMSG1L
perform SEND-PRIMARY-SCREEN
* Should never get to here...
exit.
*****************************************************************
SEND-PRIMARY-SCREEN.
perform BUILD-HEADER-INFO
move PF-ROW-23 to PFROW23O
move 'ENTER, SEND-PRIMARY-SCREEN...' to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
EXEC CICS SEND
MAP ('DMPUA11')
FROM (DMPUA11O)
ERASE
END-EXEC
move LOW-VALUES to DMPUA11O
EXEC CICS RETURN
TRANSID (LOCAL-TRAN-ID)
COMMAREA (DMPUA11O)
LENGTH (32)
END-EXEC
* Should never get to here...
exit.
*****************************************************************
TRANSFER-CONTROL.
EXEC CICS XCTL
PROGRAM(PROGRAM-NAME)
RESP(XCTL-RESP-CODE)
END-EXEC
* Should never get to here...
move 'Program not found, &&&&&&&&' to MSG-LINES.
inspect MSG-LINES replacing first '&&&&&&&&'
by PROGRAM-NAME
move -1 to SYSMSG1L.
perform RECOVERY-ROUTINE.
* exit.
*****************************************************************
Z-GET-DATE-AND-TIME.
accept WORK-DATE from DATE YYYYMMDD
accept WORK-TIME from TIME
move 'ccyy/mm/dd' to EDIT-DATE
move WORK-DATE(1:4) to EDIT-DATE(1:4)
move WORK-DATE(5:2) to EDIT-DATE(6:2)
move WORK-DATE(7:2) to EDIT-DATE(9:2)
move EDIT-DATE to SYSDATEO
move 'hh:mm:ss.dd' to EDIT-TIME
move WORK-TIME(1:2) to EDIT-TIME(1:2)
move WORK-TIME(3:2) to EDIT-TIME(4:2)
move WORK-TIME(5:2) to EDIT-TIME(7:2)
move WORK-TIME(7:2) to EDIT-TIME(10:2)
move EDIT-TIME to SYSTIMEO
exit.
*****************************************************************
Z-GET-DATE-AND-TIME-CICS.
EXEC CICS ASKTIME END-EXEC
MOVE EIBDATE TO W2-DATE
MOVE EIBTIME TO W2-TIME
exit.
*****************************************************************
Z-POST-LOG-MESSAGE-WITH-ERASE.
perform Z-GET-DATE-AND-TIME
move LOG-MESSAGE to ESD128-RECORD
perform WRITE-TO-LOG
move SPACES to LOG-TEXT-GROUP
move SPACES to ESD128-RECORD
exit.
The Assembler Table
The following is the Assembler Source Code (TABLE002.mlc) for the non-executable load member.
***********************************************************************
* TABLE002.MLC - Test Table for ASMOGENR *
* Provided by SimoTime Technologies *
* (C) Copyright 1987-2019 All Rights Reserved *
* Web Site URL: http://www.simotime.com *
* e-mail: helpdesk@simotime.com *
***********************************************************************
*
* ..:....1....:....2....:....3....:....4....:....5....:....6....:...
*
TABLE002 CSECT 0
PARM003 DC S(ESIZE)
PARM011 DC S(ECOUNT)
DC CL1' '
ARRAY003 DS 0H
DC CL3'060'
TAG001 EQU *
ESIZE003 EQU 3
ESIZE EQU *-ARRAY003
DC CL3'010'
DC CL3'011'
DC CL3'01A'
DC CL3'020'
DC CL3'021'
DC CL3'02A'
DC CL3'02B'
DC CL3'900'
DC CL3'999'
DC CL3'99A'
ECOUNT11 EQU 11
ECOUNT EQU (*-ARRAY003)/ESIZE
TEST0003 DC S(ESIZE)
TEST0011 DC S(ECOUNT)
END
The following link describes how to generate a non-executable member for the EBCDIC or ASCII encoded environment.
Explore The technology to Generate Non-Executable Load Members from Mainframe Assembler Source Code for use with Micro Focus Enterprise Server on a Windows, Linux or UNIX System. This technology has the ability to generate a non-executable member for the EBCDIC or ASCII encoded environment.
Summary
This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the icon.
Explore The technology to Generate Non-Executable Load Members from Mainframe Assembler Source Code for use with Micro Focus Enterprise Server on a Windows, Linux or UNIX System. This technology has the ability to generate a non-executable member for the EBCDIC or ASCII encoded environment.
Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.
Explore the CICS Connection for more examples of mainframe CICS coding techniques and sample code.
Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.
Explore an Extended List of Software Technologies that are available for review and evaluation. The software technologies (or Z-Packs) provide individual programming examples, documentation and test data files in a single package. The Z-Packs are usually in zip format to reduce the amount of time to download.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connection.
This suite of programs and documentation is available for download. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Contact or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| In Memory Table Access using Temporary Storage Queue |
| Copyright © 1987-2024 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |