Traditional Data Structures
Identify and Document
  Table of Contents  v-16.01.01 - fpload01.htm 
  Introduction
  File Properties Repository
  The Excel Spreadsheets
  Delete/Define a New Repository
  Populate Repository with CSV Input
  Record Structure of the Repository
  Ancillary Functions
  Set the Environment
  Display and Log Messages
  Compiler Directives
  Technical Details
  Format of the Excel Spreadsheet
  CMD Files, Windows Environment
  Delete/Define for Repository
  Populate the Repository
  Managing a File Properties Repository
  Utility Programs, Delete/Define a Repository
  Utility Programs, Populate a Repository
  Summary
  Software Agreement and Disclaimer
  Downloads and Links
  Current Server or Internet Access
  Internet Access Required
  Glossary of Terms
  Comments or Feedback
  Company Overview
The SimoTime Home Page 

Table of Contents Previous Section Next Section Introduction

This suite of programs will provide the capability of creating and managing a repository of file properties (FPMASTER) for Data Files, Partitioned Data Sets (PDS) and GDG Base definitions used by a mainframe application or group of applications. This capability and the information it provides is quite useful when supporting applications or migrating an application (source code, control information and data) from a Mainframe System to a Linux, UNIX or Windows (LUW) System using Micro Focus technologies.

The FPMASTER (or File Properties Repository) is a Micro Focus Key-Sequenced-Data Set. Two Programs are provided that provide the capability of importing or extracting information between the FPMASTER and a Microsoft Excel spreadsheet. A comma-separated-values (CSV) file is used as the exchange format between FPMASTER and Excel.

A batch interface to load or update the File Properties Repository is provided. This batch interface uses a record sequential file as input. The record structure is a Fixed Field Length (FFL) format. A COBOL copy file is provided for the record layout.

The scripts, programs, data sets and documentation for the File Properties Repository Management are provided in a single zipped file called FPMAST01.ZIP. This zipped file may be downloaded from the SimoTime Web site. This example illustrates the following functions.

Script Description
FPDDEFE1 Delete/Define a VSAM cluster (or Micro Focus Key-Sequenced-File) that will be used as the File Properties Repository.
FPMIMPE1 Demonstrate how to populate the File Properties Repository (or VSAM, KSDS) with information from an Excel spreadsheet that has been saved as a Comma-Separated-Values (or CSV) file.
FPMEXPE1 Demonstrate how to access the File Properties repository (or VSAM, KSDS) and write information to a CSV file that may be easily exported into an Excel spreadsheet.
FPLOADE1 Describe how to use the "Batch Interface" load program to do the initial load of a File Properties Repository.
FPMUPDE1 Describe how to use the "Batch Interface" update program to add or update records in the File Properties Repository.
  Supplied Commands for the File Repository Management Tasks

This suite of programs will work in a complementary manner with the following technologies available from SimoTime.

Link Description
JCLSCAN01 Provides the utility programs to scan JCL members and extract information from DD statements and IDCAMS control specifications.
DATRAK01 Describes various methods for collecting file information to build a File Properties repository.
CATPOP01 Provides the utility programs to use the information stored in the File Properties repository to create the catalog entries to be used by Micro Focus Mainframe Express, Studio Enterprise Edition or Server Enterprise Edition.
  Complementary Technologies for File Repository Management

We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.

Copyright © 1987-2017
SimoTime Technologies
All Rights Reserved

Table of Contents Previous Section Next Section File Properties Repository

This section describes the process for creating and populating a File Properties Repository using the information from Excel spread sheets as input to the process.

Table of Contents Previous Section Next Section The Excel Spreadsheets

Refer to the Technical Details, Format of the Excel Spreadsheet for details of how to use Excel spreadsheets to capture information about the files used by an application. Once the information is captured save the spreadsheets as Comma Separated Values (or CSV) files. The location and name of the CSV files used in the example are as follows.

CSV File Name Description
LONAPGDG.CSV List of GDG Base and Model structures that will be used to populate the File Properties Repository.
LONAPKSD.CSV List of VSAM, Key-Sequenced-Data-Sets (KSDS) that will be used to populate the File Properties Repository.
LONAPPDS.CSV List of Partitioned Data Sets (PDS's) that will be used to populate the File Properties Repository.
LONAPSEQ.CSV List of Record Sequential Data Files that will be used to populate the File Properties Repository.
LONAPX10.CSV List of additional files (such as VSAM, ESDS) that will be used to populate the File Properties Repository.
  List of CSV Files used to Populate the File Properties Repository

Table of Contents Previous Section Next Section Delete/Define a New Repository

Run the following command to create a new File Properties Repository (FPMASTER.DAT).

C:\SIMOSAM1\DEVL\ADM1> FPDDEFE1 

Table of Contents Previous Section Next Section Populate Repository with CSV Input

Run the following command to populate a new File Properties Repository (FPMASTER.DAT).

C:\SIMOSAM1\DEVL\ADM1> FPMIMPE1 

Table of Contents Previous Section Next Section Record Structure of the Repository

The following COBOL copy file (FPMASTB1.cpy) shows the record layout for the file inventory data base.

      *****************************************************************
      *               FPMASTB1.CPY - a COBOL Copy File                *
      *         Copyright (C) 1987-2017 SimoTime Technologies         *
      *                     All Rights Reserved                       *
      *              Provided by SimoTime Technologies                *
      *        Our e-mail address is: helpdesk@simotime.com           *
      *     Also, visit our Web Site at http://www.simotime.com       *
      *****************************************************************
      * Copy File for the record structure of the FPMASTER File that
      * contains the properties or characteristics of non-relational
      * data structures, Sequential file or VSAM Data Sets.
      * This is a VSAM Keyed=Sequential-Data-Set or Key-Indexed File. *
      *
       01  FPMASTER-REC.
           05  FPMASTER-DATA-01.
               10 FPMASTER-BASE-INFO.
                   15  FPMASTER-LEVEL-NBR  PIC 9(2).                    COL-A
                   15  FPMASTER-DSN-NAME   PIC X(54).                   COL-B
                   15  FPMASTER-DD-NAME    PIC X(17).                   COL-C
               10  FPMASTER-FILE-PROPERTIES.
                   15  FPMASTER-DCB-DSORG  PIC X(4).                    COL-D
                   15  FPMASTER-DCB-RECFM  PIC X(4).                    COL-E
                   15  FPMASTER-MIN-LRECL  PIC 9(5).                    COL-F
                   15  FPMASTER-MAX-LRECL  PIC 9(5).                    COL-G
                   15  FPMASTER-KEY-POS    PIC 9(5).                    COL-H
                   15  FPMASTER-KEY-LEN    PIC 9(5).                    COL-I
                   15  FPMASTER-VSAM-DAT   PIC X(44).                   COL-J
                   15  FPMASTER-VSAM-IDX   PIC X(44).                   COL-K
               10  FPMASTER-JOB-INFO.
                   15  FPMASTER-JCL-OVR1   PIC X(8).                    COL-L
                   15  FPMASTER-JCL-USR1   PIC X(8).                    COL-M
                   15  FPMASTER-JCL-USR2   PIC X(8).                    COL-N
               10  FPMASTER-EXTENDED-INFO.
                   15  FPMASTER-EXTEND-S1  PIC X(4).                    COL-O
                   15  FPMASTER-EXTEND-S2  PIC X(4).                    COL-P
                   15  FPMASTER-EXTEND-M1  PIC X(16).                   COL-Q
                   15  FPMASTER-EXTEND-M2  PIC X(16).                   COL-R
                   15  FPMASTER-EXTEND-M3  PIC X(16).                   COL-S
                   15  FPMASTER-EXTEND-M4  PIC X(16).                   COL-T
                   15  FPMASTER-EXTEND-X1  PIC X(256).                  COL-U
                   15  FPMASTER-EXTEND-X2  PIC X(256).                  COL-V
               10  FILLER                  PIC X(227).
      *
      ***  FPMASTB1 - End-of-Copy File - - - - - - - - - - - FPMASTB1 *
      *****************************************************************
      *

Table of Contents Previous Section Next Section Ancillary Functions

This section provides technical detail about the supporting scripts and programs used or called by the primary jobs.

Table of Contents Previous Section Next Section Set the Environment

A command file (ENV1BASE.cmd) is called from other command files to set commonly used environment variables. This provides a single point of definition. The following is a listing of the contents of the command file.

@echo OFF
rem  * *******************************************************************
rem  *               ENV1BASE.cmd - a Windows Command File               *
rem  *        This program is provided by SimoTime Technologies          *
rem  *           (C) Copyright 1987-2017 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Provide a single point to set common environment variables.
rem  * Author - SimoTime Technologies
rem  * Date   - January 24, 1996
rem  *
rem  * Set the commonly used environment variables. This is used to provide
rem  * a single point for managing the commonly used environment variables.
rem  *
     set SimoLIBR=c:\SimoLIBR
     set BASELIB1=c:\SIMOSAM1\DEVL
     set BASELIB8=c:\SimoSAM8
     set BaseWIP1=c:\SimoSAM1\WIP1
     set DATAZERO=c:\SIMODATA\DEVL\DATA\ZERO
     set BASEAPP=%BaseLib1%
     set BASESYS=%BaseLib1%\SYS1
     set BASECAT=%BaseLib1%\DATA
     set SYSLOG=%BASESYS%\LOGS\SYSLOG_USER.DAT
     set SYSOUT=%BASEAPP%\LOGS\SYSOUT_SIMSAM01.TXT
     set SLZMSG=%BASEAPP%\LOGS\SLZMSG_USER.TXT
     set PostNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.TXT
     set SimoNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.TXT
     call SIMONOTE "* SIMONOTE Log File is %SIMONOTE% "
rem  *
     set MQBASE=C:\Program Files\IBM\WebSphere MQ
rem  *
rem  * Set the location for the Apache-Tomcat Server...
     set CATALINA_HOME=C:\APACHETC\apache-tomcat-7.0.52
rem  *
rem  * Set the Environment for the Java Environment...
     set JAVABASE=C:\Program Files (x86)\Java\jdk1.8.0_112
     set JAVASDK="%JAVABASE%\bin"
     set JAVA_HOME=%JAVABASE%
     set JRE_HOME=%JAVABASE%
rem  *
rem  * Set the environment for the Micro Focus technology...
     set MIFOEDEV=C:\Program Files (x86)\Micro Focus\Enterprise Developer
     set MIFOVCBL=C:\Program Files (x86)\Micro Focus\Visual COBOL
     set MIFOESTU=C:\Program Files (x86)\Micro Focus\Studio Enterprise Edition 6.0
     set MIFOEMFE="C:\Program Files (x86)\Micro Focus\Mainframe Express"
rem  *
rem  * Large file support, performance tuning and record locking of the File Handler
     set EXTFH=%BASESYS%\CONFIG\EXTFHBIG.CFG
rem  *
rem  * For IMS Support
     set ES_IMSLIB=%BASEAPP%\IMSLIB
     set ES_ACBLIB=%BASEAPP%\IMSLIB
rem  *
rem  * EZASOKETS Check EZASOKETS Enabled box or set ES_EZASOKET_SUPPORT=YES
     set EZACONFG=BASESYS1\CONFIG\EZACONFG.dat
rem  *
rem  * Resource Allocation and Performance for SORT and non-Relational Data
rem  set MFJSENGINE=SYNCSORT
     set SORTSCHEME=1
     set SORTSPACE=750000000
     set TMP=C:\SORTWORK
rem  *
     set ES_ALLOC_OVERRIDE=%BASESYS%\CONFIG\CATMAPA1.cfg
rem  * For CORE_ON_ERROR function, ABEND Dump
rem  *     set COBCONFIG_=%BASESYS%\CONFIG\diagnose.cfg
rem  *
rem  * Consolidated Trace Facility (CTF)
rem  *     set MFTRACE_CONFIG=%BASESYS%\CONFIG\ctf.cfg
rem  *     set MFTRACE_LOGS=c:\ctflogs
rem  *
rem  * For Job Restart, ABEND Recovery
     set MF_UCC11=Y
     set ES_JES_RESTART=Y
rem  *
rem  * Set environment for MFBSI (Micro Focus Batch Scheduling Interface)
     set ES_EMP_EXIT_1=mfbsiemx
     set MFBSI_DIR=%BASESYS%\LOGS\%JESSERVERNAME%
     set MFBSIEOP_CMD=ENABLE
     set MFBSIEOP_CSV=ENABLE
     set MFBSIEOP_HTM=ENABLE
     set MFBSIEOP_XML=ENABLE
rem  *
rem  * Set Behavior and Trace Flags for GETJOBDD
rem  *   Position=12345678/12345678
     set JDDFLAGS=nnnWnnnn/YYnnnnnn
rem  *
     set MAINFRAME_FLOATING_POINT=true
     set COBIDY=%BASEAPP%\COBIDY
     set COBPATH=.;%BASEAPP%\LOADLIB;%BASESYS%\LOADLIB;%SimoLIBR%
     set LIBPATH=.;%BASEAPP%\LOADLIB;%BASESYS%\LOADLIB;%SimoLIBR%
     set TXDIR=%BASESYS%\LOADLIB;%MIFOBASE%
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%
rem  *
rem  * If not already set then set the PATH for Micro Focus Directories
     if "%SIMOPATH%" == "Y" goto JUMPPATH
     if "%MIFOSYS1%" == "EDEV" goto JUMPEDEV
     if "%MIFOSYS1%" == "VCBL" goto JUMPVCBL
     if "%MIFOSYS1%" == "ESTU" goto JUMPESTU
     if "%MIFOSYS1%" == "EMFE" goto JUMPEMFE
:JUMPEDEV
     set path=%BASESYS%\LOADLIB;%MIFOEDEV%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOEDEV%\CPYLIB
     set MIFOBASE=%MIFOEDEV%
     goto JUMPPATH
:JUMPVCBL
     set path=%MIFOVCBL%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set MIFOBASE=%MIFOVCBL%
     goto JUMPPATH
:JUMPESTU
     set MIFOBASE=%MIFOESTU%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
:JUMPEMFE
     set MIFOBASE=%MIFOEMFE%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
rem  *
:JUMPPATH
     set SIMOPATH=Y
rem  *
     set USERCLASS=%BASELIB1%\LOADLIB
     set CLASSPATH=.
     set CLASSPATH=%CLASSPATH%;%JAVABASE%
     set CLASSPATH=%CLASSPATH%;%JAVABASE%\lib
     set CLASSPATH=%CLASSPATH%;\%USERCLASS%\simpacks
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes\simpacks
     if "%MIFOSYS1%" == "ESTU" set CLASSPATH=%CLASSPATH%;%MIFOBIN%
     if "%MIFOSYS1%" == "EDEV" set CLASSPATH=%CLASSPATH%;%MIFOEDEV%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%\mfcobol.jar
rem  *
     set JobStatus=0000
     call SimoNOTE "* Settings CmdName ENV1BASE.cmd, Version 14.03.28, %MIFOSYS1%"
     call SimoNOTE "* BaseAPP ..... %BASEAPP%"
rem *      call SimoNOTE "* MFBSIDIR .... %MFBSI_DIR% "
     call SimoNOTE "* MIFOSYS1 is %MIFOSYS1% "
     call SimoNOTE "* MIFOBASE is %MIFOBASE% "
     call SimoNOTE "* SIMOLIBR is %SIMOLIBR% "

Table of Contents Previous Section Next Section Display and Log Messages

A command file (SIMONOTE.cmd) is called from other command files to display messages to the screen and write the message to a log file in a consistent manner. The following is a listing of the contents of the command file.

@echo OFF
rem  * *******************************************************************
rem  *               SIMONOTE.CMD - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *            (C) Copyright 1987-2016 All Rights Reserved            *
rem  *              Web Site URL:   http://www.simotime.com              *
rem  *                    e-mail:   helpdesk@simotime.com                *
rem  * *******************************************************************
rem  *
rem  * Text    - Display message on screen and write to a log file.
rem  * Author  - SimoTime Technologies
rem  *
rem  * This script may be called from other scripts and expects a single
rem  * parameter enclosed in double quotes. The double quotes will be
rem  * removed. Before writing to the log file a date and time stamp
rem  * will be inserted in front of the message text.
rem  *
rem  * Note: The tilde (~) removes leading/trailing double-quotes.
rem  *
if "%SimoNOTE%" == "" set SimoNOTE=c:\SimoLIBR\LOGS\SimoTime.LOG
echo %date% %time% %~1>> %SimoNOTE%
echo %~1

Table of Contents Previous Section Next Section Compiler Directives

A directives file (ActiveMFAsc.DIR) containing the following directives was used to compile and test the programs used in this suite of programs. The file contains the following directives (or compiler options).

DIALECT"MF"
CHARSET"ASCII"
ASSIGN"EXTERNAL"
IBMCOMP
NOTRUNC
RTNCODE-SIZE"2"
ANIM
NOQUERY
DEFAULTBYTE"00"
NOOPTIONAL-FILE
outdd"SYSOUT 121 L"
SHARE-OUTDD
DATAMAP
settings
list()
noform

Table of Contents Previous Section Next Section Technical Details

This section provides a technical overview of the programs used to manage the File Properties Repository and a description of the programs and procedures that provide additional functionality.

Table of Contents Previous Section Next Section Format of the Excel Spreadsheet

The following is the column structure for an Excel spreadsheet to be used as a starting point to populate the catalog.

Column - Label Description
A - Level Number This should be a "1" for the primary file definition information. A zero (0) is used to define the row that is used for column headers.
B - DSN This is a text string with a maximum length of forty-four (44) characters. It is the fully-qualified MVS Data Set Name (DSN) or VSAM Cluster Name
C - DD Name This is a text string with a maximum length of eight (8) characters. It is the DD Name.
D - DSORG This is the Data Set Organization.
E - RECFM This is the Record Format.
F - lrecl-MIN This is a numeric string with a maximum length of five (5) digits. It is the minimum or average record length.
G - lrecl-MAX This is a numeric string with a maximum length of five (5) digits. It is the maximum record length.
H - KeyPos This is a numeric string with a maximum length of five (5) digits. It is the key starting position. The first position in a record is 1
I - KeyLen This is a numeric string with a maximum length of five (5) digits. It is for the length of the key.
J - VSAM Data Name This is a text string with a maximum length of forty-four (44) characters. It is the VSAM Data Name for KSDS and ESDS
K - VSAM Index Name This is a text string with a maximum length of forty-four (44) characters. It is the VSAM Index Name for KSDS
L - Override Job This is a text string with a maximum length of eight (8) characters. It is the JCL Member name that will be used to override the generated JCL that is used to create the catalog entry.
M - User Job 1 This is a text string with a maximum length of eight (8) characters. It is the JCL Member name for a job that will be submitted to the internal reader after the catalog creation process is complete.
N - User Job 2 This is a text string with a maximum length of eight (8) characters. It is the JCL Member name for a job that will be submitted to the internal reader after the previous steps are completed.
O - Extended S1 This is a text string with a maximum length of four (4) characters. The content varies.
If DSORG=PO then this field contains the extension of the PDSM that is used for a dynamic PDS.
P - Extended S2 This is a text string with a maximum length of four (4) characters. The content varies.
Q - Extended M1 This is a text string with a maximum length of sixteen (16) characters. The content varies, refer to Note-1
R - Extended M2 This is a text string with a maximum length of sixteen (16) characters. The content varies, refer to Note-1
S - Extended M3 This is a text string with a maximum length of sixteen (16) characters. The content varies, refer to Note-1
T - Extended M4 This is a text string with a maximum length of sixteen (16) characters. The content varies, refer to Note-1
U - Extended X1 This is a text string with a maximum length of 256 characters. It is the path to the directory that contains the Members for a Job Override, User Job 1 and/or User Job 2.
V - Extended X2 This is a text string with a maximum length of 256 characters. The content varies.
If DSORG=PO then this field contains the path to the directory that contains the PDS Members.
Note-1: The Extended M1 trhough M4 fields are sixteen (16) byte fields. The content varies.
If DSORG=GDG the following values are accepted:
 LIMIT(nnn) where nnn is the number of active generations
 SCRATCH or NOSCRATCH, SCRATCH will physically delete the generation, NOSCRATCH will uncatalog the latest generation
 NOEMPTY or EMPTY, This specifies, what action is to be taken when the GDG becomes full base on the number in the LIMIT.
  Format of an Excel Spread Sheet

Table of Contents Previous Section Next Section CMD Files, Windows Environment

This section will focus on the Windows environment and the Command files (or scripts) that are used to create and manage the File Properties Repository.

Table of Contents Previous Section Next Section Delete/Define for Repository

This command (FPDDEFE1.cmd) will create (or Delete/Define) a new Micro Focus Keyed-Indexed file that will be used as the File Properties Repository.

@echo OFF
rem  * *******************************************************************
rem  *               FPDDEFE1.CMD - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2017 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  * A procedure for a batch function to create a new FPMASTER.DAT
rem  * file that will be used as the File Properties Repository. This
rem  * process performs the same function as an IDCAMS, Delete/Define.
rem  *
rem  * This procedure calls the following Windows Command Files.
rem  * 1. ezSetEnv.CMD - this provides a single point for setting commonly
rem  *                   used environment variables.
rem  * 2. SimoNOTE.CMD - this provides a consistent process for displaying
rem  *                   messages to the screen and writing to a journal or
rem  *                   log file.
rem  * ************************************************************************
     setlocal
     set CmdName=FPDDEFE1
     call ..\Env1BASE %CmdName%
rem  *
     call SimoNOTE "*******************************************************************%CmdName%.CMD"
     call SimoNOTE "Starting JobName %CmdName%.CMD"
rem  *
rem  * Step 1 of 2, Prepare the Environment
rem  *              UPDFLAG-01 Update complete record
rem  *              UPDFLAG-02 Update the Base Fields (Key and File Names)
rem  *              UPDFLAG-03 Update the File Properties
rem  *              UPDFLAG-04 Update the JCL Scan Fields
rem  *              UPDFLAG-05 Update the User defined Fields
rem  *
rem  *            12345678
     set UPDFLAGS=NYYYN
     set FPRFFLD1=%BaseLib1%\Adm1\DATA\Wrk1\SIMOTIME.UTIL.FPNULLD1.DAT
     set FPMASTER=%BaseLib1%\Adm1\DATA\UTIL\SIMOTIME.UTIL.FPMASTER.DAT
rem  *
rem  * The following will create a null sequnetial file for input. This will
rem  * be used to force an end of file and create an empty FPMASTER.DAT file
rem  * to be used as the File Properties Repository.
rem  *
     if not exist %FPRFFLD1% copy nul %FPRFFLD1%
rem  *
rem  * Step 2 of 2, Update or Add records to the Data FIle Data Base
rem  *
rem  * Read the Listing file, set the environment and append/update the
rem  * records in the File Properties Repository. Since the input file
rem  * is an empty file this will perform a Delete/Define for a new,
rem  * File Properties Repository (or FPMASTER.DAT).
rem  *
     run FPLOADC1
     if not "%ERRORLEVEL%" == "0" (call SimoNOTE "Error Level = %ERRORLEVEL% "
                                   set JobStatus=0010)
     if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
     call SimoNOTE "DataMake %FPMASTER%"
     call SimoNOTE "Finished CmdName %CmdName%, Job Status is %JobStatus% "
     goto :End
:EojNOK
     call SimoNOTE "ABENDING CmdName %CmdName%, Job Status is %JobStatus% "
     goto :End
:End
     call SimoNOTE "FileInfo SYSOUT=%SYSOUT%"
     call SimoNOTE "Finished JobName %CmdName%.CMD"
     if not "%SimoGENS%" == "BATCH" pause
     endlocal

Table of Contents Previous Section Next Section Populate the Repository

This script (FPMIMPE1.cmd) will read an ASCII/Text file and use the information in the individual records to update the File Properties Repository. The ASCII/Text file is created by saving an Excel Spreadsheet as a Comma Separated Values (or CSV) file.

@echo OFF
rem  * *******************************************************************
rem  *               FPMIMPE1.CMD - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2015 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  * This procedure will read an ASCII/Text file and use the information
rem  * in the individual records to update the File Properties Repository.
rem  * The ASCII/Text file is created by saving an Excel Spreadsheet as a
rem  * Comma Separated Values (or CSV) file.
rem  *
rem  * This procedure calls the following Windows Command Files.
rem  * 1. ezSetEnv.CMD - provides a single point for setting commonly
rem  *                   used environment variables.
rem  * 2. SimoNOTE.CMD - provides a consistent process for displaying
rem  *                   messages to the screen and writing to a journal
rem  *                   or log file.
rem  * *******************************************************************
     setlocal
     set CmdName=FPMIMPE1
     call ..\Env1BASE %CmdName%
rem  *
     call SimoNOTE "*******************************************************************%CmdName%.CMD"
     call SimoNOTE "Starting JobName %CmdName%.CMD"
rem  *
     set FPMASTER=%BaseLib1%\Adm1\DATA\UTIL\SIMOTIME.UTIL.FPMASTER.DAT
rem  *
rem  * Read the CSV File, update the FPMASTER File (File Properties Repository).
     set FPASCCSV=%BASECAT%\XLSS\LONAPPDS.CSV
     call SimoNOTE "DataTake %FPASCCSV%"
     run FPMIMPC1
     if not "%ERRORLEVEL%" == "0" (call SimoNOTE "Error Level = %ERRORLEVEL% "
                                   set JobStatus=0010)
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
rem  * Read the CSV File, update the FPMASTER File (File Properties Repository).
     set FPASCCSV=%BaseLib1%\DATA\XLSS\LONAPGDG.CSV
     call SimoNOTE "DataTake %FPASCCSV%"
     run FPMIMPC1
     if not "%ERRORLEVEL%" == "0" (call SimoNOTE "Error Level = %ERRORLEVEL% "
                                   set JobStatus=0020)
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
rem  * Read the CSV File, update the FPMASTER File (File Properties Repository).
     set FPASCCSV=%BaseLib1%\DATA\XLSS\LONAPSEQ.CSV
     call SimoNOTE "DataTake %FPASCCSV%"
     run FPMIMPC1
     if not "%ERRORLEVEL%" == "0" (call SimoNOTE "Error Level = %ERRORLEVEL% "
                                   set JobStatus=0030)
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
rem  * Read the CSV File, update the FPMASTER File (File Properties Repository).
     set FPASCCSV=%BaseLib1%\DATA\XLSS\LONAPKSD.CSV
     call SimoNOTE "DataTake %FPASCCSV%"
     run FPMIMPC1
     if not "%ERRORLEVEL%" == "0" (call SimoNOTE "Error Level = %ERRORLEVEL% "
                                   set JobStatus=0040)
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
rem  * Read the CSV File, update the FPMASTER File (File Properties Repository).
     set FPASCCSV=%BaseLib1%\DATA\XLSS\LONAPX10.CSV
     call SimoNOTE "DataTake %FPASCCSV%"
     run FPMIMPC1
     if not "%ERRORLEVEL%" == "0" (call SimoNOTE "Error Level = %ERRORLEVEL% "
                                   set JobStatus=0050)
     if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
     call SimoNOTE "DataTake %FPASCCSV%"
     call SimoNOTE "DataMake %FPMASTER%"
     call SimoNOTE "Finished CmdName %CmdName%, Job Status is %JobStatus% "
     goto :End
:EojNOK
     call SimoNOTE "ABENDING CmdName %CmdName%, Job Status is %JobStatus% "
     goto :End
:End
     call SimoNOTE "FileInfo SYSOUT=%SYSOUT%"
     call SimoNOTE "Finished JobName %CmdName%.CMD"
     if not "%SimoGENS%" == "BATCH" pause
     endlocal

Table of Contents Previous Section Next Section Managing a File Properties Repository

This section describes the utility programs used to support the creation, management and use of the File Properties Repository.

Table of Contents Previous Section Next Section Utility Programs, Delete/Define a Repository

This program (FPLOADC1.GNT) will read an ASCII/Text file and use the information in the individual records to populate the File Properties Repository. This program is intended to be used to do the initial load of the File Properties Repository.

The ASCII/Text file (or input file) is created by saving an Excel Spreadsheet as a Comma Separated Values (or CSV) file. Since this program opens the File Properties Repository file as output and if the input file is a nul file (i.e. empty file) this program will simply create (i.e. Delete/Define) a new File Properties Repository (FPMASTER.DAT).

Table of Contents Previous Section Next Section Utility Programs, Populate a Repository

This set of programs (FPMIMPC1.CBL and FPMIMPR1.CBL) will read an ASCII/Text file (with records in a Comma Separated Values format) and use the information in the individual records to populate the File Properties Repository (with records in a Fixed Field Length format). This set of programs is intended to be used to import data from an Excel spreadsheet into the File Properties Repository. The first program performs the file I/O and calls the second program to do the actual record format conversion.

Table of Contents Previous Section Next Section Summary

This suite of programs will provide the capability of creating and managing a repository of file properties (FPMASTER) for Data Files, Partitioned Data Sets (PDS) and GDG Base definitions used by a mainframe application or group of applications. This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.

In the world of programming there are many ways to solve a problem. This document and the links to other documents are intended to provide a greater awareness of the Data Management and Application Processing alternatives.

The documentation and software were developed and tested on systems that are configured for a SimoTime environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.

SimoTime Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SimoTime Services or Technologies please send an e-mail to: helpdesk@simotime.com or call 415 883-6565. We appreciate hearing from you.

Table of Contents Previous Section Next Section Software Agreement and Disclaimer

Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.

SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.

Table of Contents Previous Section Next Section Downloads and Links

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.

Note: A SimoTime License is required for the items to be made available on a local system or server.

Table of Contents Previous Section Next Section Current Server or Internet Access

The following links may be to the current server or to the Internet.

Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the Link to Internet icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the Link to Server icon.

Link to Internet   Link to Server   Explore how to manage a Repository of Information about Data Files used by an application or suite of applications. This link will focus on non-relational data structures such as traditional files, VSAM Data Sets, Partitioned Data Sets (PDS's) and Generation Data Groups (GDG's). The repository is a VSAM, Key-Sequenced-Data-Set (KSDS).

Link to Internet   Link to Server   Explore an example of a generated HTML document that contains the details (or properties) of the non-relational data structures used by an application. This link will focus on non-relational data structures such as traditional files, VSAM Data Sets, Partitioned Data Sets (PDS's) and Generation Data Groups (GDG's).

Link to Internet   Link to Server   Explore a CICS Sample Program for accessing the FPMASTER File. The FPMASTER File contains information (or properties) about the non-relational data structures used by the sample applications. The repository is a VSAM, Key-Sequenced-Data-Set (KSDS)

Link to Internet   Link to Server   Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.

Link to Internet   Link to Server   Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.

Link to Internet   Link to Server   Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.

Link to Internet   Link to Server   Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and/or QSAM files.

Table of Contents Previous Section Next Section Internet Access Required

The following links will require an internet connect.

This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.

A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection

Explore The Micro Focus Web Site for more information about products and services available from Micro Focus. This link requires an Internet Connection.

Table of Contents Previous Section Next Section Glossary of Terms

Link to Internet   Link to Server   Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.

Table of Contents Previous Section Next Section Comments or Feedback

This document was created and is copyrighted and maintained by SimoTime Technologies.

If you have any questions, suggestions, comments or feedback please call or send an e-mail to: helpdesk@simotime.com

We appreciate hearing from you.

Table of Contents Previous Section Next Section Company Overview

SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.

Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.

Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.

Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com


Return-to-Top
Traditional Data Structures, Identify and Document
Copyright © 1987-2017
SimoTime Technologies and Services
All Rights Reserved
When technology complements business
http://www.simotime.com