Generate & Transfer
Regression Test, Document Record Layout
  Table of Contents  v-18.09.15 - rtw00608.htm 
  Introduction
  Job Flow Diagram
  Job Flow Overview
  Technical Details
  Primary Job Script
  Generate, Function Test 01
  Ancillary Functionality
  Set the Environment
  Display and Log Messages
  Summary
  Software Agreement and Disclaimer
  Downloads and Links
  Current Server or Internet Access
  Internet Access Required
  Glossary of Terms
  Comments or Feedback
  Company Overview
The SimoTime Home Page 

Table of Contents Previous Section Next Section Introduction

This Job Script will generate the HTML documentation for the record layout of non-relational data structures that includes Traditional Files or VSAM Data Sets.


We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.

Copyright © 1987-2019
SimoTime Technologies and Services
All Rights Reserved

Table of Contents Previous Section Next Section Job Flow Diagram

The following shows the sequencing of events and processing tasks that are used to generate, transfer and compile a suite of programs that will generate the HTML documentation.

             
RTW006W8
* Primary Job Script
   
call
 
 
ENV1BASE
* Prepare the System Environment
   
call
 
 
USERCOGI
* Prepare the Data & Job Environment
   
FOR Loop
 
 
   
   
* Function Test 01
   
   
   
   
   
   
RTCPYHTM
* Generate the HTML Document
   
   
   
REC1CPY1
lseq
 
 
SIMOREC1
 
 
REC1HTML
html
* SimoTime Utility program
   
   
   
   
   
EOJ
* End of Job Processing
 
Generate the HTML Documents for Record Structures

Table of Contents Previous Section Next Section Job Flow Overview

The following describes the Job Scripts and Programs that are used to generate, transfer and compile a suite of programs that will generate the HTML documentation.

1. Execute the Primary Job Script, RTW006W8
1.1. Prepare the System Environment
1.2. Prepare the User Data and Job Environment
2. Function Test 01, Document Generation process
2.1. Call RTCPYHTM, a secondary Job Script
2.1.1. Run the SIMOREC1 Utility program
3. End of Job Processing

Table of Contents Previous Section Next Section Technical Details

The following provides an in-depth look at the Job Scripts used to generate the HTML documentation for the record layout of non-relational data structures that includes Traditional Files or VSAM Data Sets.

Table of Contents Previous Section Next Section Primary Job Script

The following (RTW006W8.cmd) is the primary Job Script that is used for regression testing.

@echo OFF
     set CmdName=RTW006W8
rem  * *******************************************************************
rem  *                 RTW006W8.cmd - a Windows Command File             *
rem  *         This Job Script is provided by SimoTime Technologies      *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  * This job will read a file containing a list of names of the
rem  * COBOL Copy Files that define record structures. For each COBOL
rem  * copy File name the RTCPYHTM.cmd is called to do the HTML document
rem  * generation.
rem  *
rem  * This procedure calls the following Windows Command Files.
rem  * 1. ENV1BASE.cmd - this provides a single point for setting commonly
rem  *                   used environment variables.
rem  * 2. USERCOGI.cmd - define the user directories for input and output.
rem  * 3. SIMONOTE.cmd - this provides a consistent process for displaying
rem  *                   messages to the screen and writing to a journal
rem  *                   or log file.
rem  * 4. RTCPYHTM.cmd - this will do the actual HTML generation for a
rem  *                   record structure based on the field definitions
rem  *                   in a COBOL copyfile.
rem  * *******************************************************************
rem  *
rem  *                   ************
rem  *                   * RT006W8 *    * Job Name for Windows
rem  *                   ********cmd*
rem  *                        *
rem  *                   ************
rem  *                   * ENV1BASE *    * Prepare System Environment
rem  *                   ********cmd*
rem  *                        *
rem  *                   ************
rem  *                   * USERCOGI *    * Prepare Job Environment
rem  *                   ********cmd*
rem  *                        *
rem  *  ************     ************
rem  *  * MBR_LIST *-----* FOR_Loop *----------*
rem  *  *******lseq*     ************          *
rem  *                        *                *
rem  *                *-------*                *
rem  *                *                   ************
rem  *                *                   * RTCPYHTM *
rem  *                *                   ********cmd*
rem  *                *                        *
rem  *                *  ************     ************     ************
rem  *                *  * REC1COPY *-----* SIMOREC1 *-----* REC1HTML *
rem  *                *  *******lseq*     ********utl*     *******lseq*
rem  *                *
rem  *                *-------*
rem  *                        *
rem  *                   ************
rem  *                   *   EOJ    *
rem  *                   ************
rem  *
rem  * *******************************************************************
rem  * The objective of this job is to produce the HTML documentaion for
rem  * a record structure using the field definitions from a COBOL copy
rem  * file.
rem  *
rem  * The following two call statements will set the environment variables.
rem  * The call to ENV1BASE will set the System or Global/Shared variables.
rem  * The call to USERCOGI will set the user-specific variables that are
rem  * required for a document generation process.
rem  *
     call ..\ENV1BASE
rem  *
     call SimoNOTE "************************************************************%CmdName%.cmd"
     call SimoNOTE "* Starting JobName %CmdName%.CMD"
rem  *
     call SimoNOTE "* Step 01 of 03, Prepare the Job Environment."
     call SIMONOTE "* BASELIB1 is %BASELIB1%"
     call %BASELIB1%\SIMOGENS\COGITATE\USERCOGI.cmd
     call SIMONOTE "* UTCOBCPY is %UTCOBCPY%"
rem  *
rem  * Set the variables for the success/failure counters.
     set AOK_Count=0
     set NOK_Count=0
     set UtlStatus=0000
     set JobStatus=0000
rem  *
rem  * Do not drop (or delete) the interim _genr and _spec files
rem  * and pause at the end of job.
     set SIMODROP=Y
     set SimoGENS=BATCH
echo *
rem  * The following two statements will place the work files in a specific
rem  * directory.
     set REC1IDX1=%BaseLib1%\DATA\WRK1\Rec1Idx1.DAT
     set REC1TXT1=%BaseLib1%\DATA\WRK1\Rec1Txt1.TXT
     set MBR_LIST=%BASELIB1%\SIMOGENS\COGITATE\SIMOTIME.LISTALL.CPY2HTML.lst
rem  *
     call SimoNOTE "* Step 02 of 03, Generate the HTML Documents for Record Structures."
     for /F "eol=; tokens=1,2* delims=." %%i in (%MBR_LIST%) do (call RTCPYHTM %UTCOBCPY%\%%i.cpy %UTHTMLIB%\%%i.htm IBM %%i)
rem  *
:Eoj
     call SimoNOTE "* Step 03 of 03, End of Job Processing."
     call SimoNOTE "* AOKcount Compile Count for AOK is %AOK_Count% "
     call SimoNOTE "* NOKcount Compile Count for NOK is %NOK_Count% "
     call SimoNOTE "* Finished JobName %CmdName%.CMD "
     if not "%SimoGENS%" == "BATCH" pause

Table of Contents Previous Section Next Section Generate, Function Test 01

The following (RTCPYHTM.cmd) is a secondary Job Script that is used to generate the HTML documentation for a record structure.

@echo OFF
     set TaskName=RTCPYHTM
rem  * *******************************************************************
rem  *               RTCPYHTM.cmd - a Windows Command File              *
rem  *        This job script is provided by SimoTime Technologies       *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  * This procedure will create HTML Documentation of a record layout
rem  * using a COBOL Copy File.
rem  * *******************************************************************
rem  *
rem  * Set the environment variable to use the default directives file.
     call SimoNOTE "* -------------------------------------------------------- *%TaskName%"
     call SimoNOTE "* Starting %TaskName% Prepare..... Task=Set the Task Environment"
     set ConvertStatus=0000
     set FNCASEBEHAVIOR=LL\
     set CASELIST=%UTWRKLIB%\%4_CASELIST.txt
     echo %2>%CASELIST%
     run FNCASEC1
rem  * The following statements will place the work files in a specific
rem  * directory.
     set REC1CBL2=%UTWRKLIB%\%4_REC1CBL2.txt
     set REC1IDX1=%UTWRKLIB%\%4_Rec1Idx1.DAT
     set REC1SEQ1=%UTWRKLIB%\%4_Rec1SEQ1.DAT
     set REC1TXT1=%UTWRKLIB%\%4_Rec1Txt1.TXT
     call SimoNOTE "* Continue %TaskName% Generate.... Task=Create HTML for Record Layout"
     set HTMHDRD1=%SimoLIBR%\rec1hdr1.htm
     set HTMFTRD1=%SimoLIBR%\rec1ftr1.htm
     set REC1COPY=%1
     set Rec1HTML=%2
     run SIMOREC1 %3 HTML
rem  *     call REC1HTML %1 %2 IBM HTML
     if not "%ERRORLEVEL%" == "0" set ConvertStatus=0010
     if not "%ConvertStatus%" == "0000" goto :ConvertEojNOK
rem  *
rem  * *******************************************************************
:ConvertEojAOK
     set /A AOK_Count=%AOK_Count% + 1
     call SimoNOTE "* DATATAKE %REC1COPY%"
     call SimoNOTE "* DATAMAKE %REC1HTML%"
     call SimoNOTE "* Complete %TaskName% RC=%ConvertStatus%, REC1COPY=%1"
     goto :End
rem  *
rem  * *******************************************************************
:ConvertEojNOK
     set JobStatus=%ConvertStatus%
     set /A NOK_Count=%NOK_Count% + 1
     call SimoNOTE "* ABENDING %TaskName%  RC=%ConvertStatus%, REC1COPY=%1, !!!ABENDING!!!"
     goto :End
rem  *
rem  * *******************************************************************
:End

Table of Contents Previous Section Next Section Ancillary Functionality

This section provides additional detail about the CMD files and programs that are used to support this set of sample programs.

Link to Internet   Link to Server   Explore How to use Common or Shared Routines that perform repetitive tasks in a consistent manner. This link will provide information about setting common environment variables and many other utilitarian tasks.

Table of Contents Previous Section Next Section Set the Environment

A command file (ENV1BASE.cmd) is called from other command files to set commonly used environment variables. This provides a single point of definition. The following is a listing of the contents of the command file.

@echo OFF
rem  * *******************************************************************
rem  *               ENV1BASE.cmd - a Windows Command File               *
rem  *        This program is provided by SimoTime Technologies          *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Provide a single point to set common environment variables.
rem  * Author - SimoTime Technologies
rem  * Date   - January 24, 1996
rem  *
rem  * Set the commonly used environment variables. This is used to provide
rem  * a single point for managing the commonly used environment variables.
rem  *
     set SimoLIBR=c:\SimoLIBR
     set BASELIB1=c:\SIMOSAM1\DEVL
     set BASELIB8=c:\SimoSAM8
     set BaseWIP1=c:\SimoSAM1\WIP1
     set DATAZERO=c:\SIMODATA\DEVL\DATA\ZERO
     set BASEAPP=%BaseLib1%
     set BASESYS=%BaseLib1%\SYS1
     set BASECAT=%BaseLib1%\DATA
     set UMAPALIB=%BASECAT%\ASC1
     set UMAPELIB=%BASECAT%\EBC1
     set SYSLOG=%BASESYS%\LOGS\SYSLOG_USER.DAT
     set SYSOUT=%BASEAPP%\LOGS\SYSOUT_SIMSAM01.txt
     set SLZMSG=%BASEAPP%\LOGS\SLZMSG_USER.TXT
     set PostNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.TXT
     set SimoNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.txt
     call SIMONOTE "* SIMONOTE Job Log File is %SIMONOTE% "
rem  *
     set MQBASE=C:\Program Files\IBM\WebSphere MQ
rem  *
rem  * Set the location for the Apache-Tomcat Server...
     set CATALINA_HOME=C:\APACHETC\apache-tomcat-7.0.52
rem  *
rem  * Set the Environment for the Java Environment...
     set JAVABASE=C:\Program Files (x86)\Java\jdk1.8.0_112
     set JAVASDK="%JAVABASE%\bin"
     set JAVA_HOME=%JAVABASE%
     set JRE_HOME=%JAVABASE%
rem  *
rem  * Set the environment for the Micro Focus technology...
     set MIFOEDEV=C:\Program Files (x86)\Micro Focus\Enterprise Developer
     set MIFOVCBL=C:\Program Files (x86)\Micro Focus\Visual COBOL
     set MIFOESTU=C:\Program Files (x86)\Micro Focus\Studio Enterprise Edition 6.0
     set MIFOEMFE="C:\Program Files (x86)\Micro Focus\Mainframe Express"
rem  *
rem  * Large file support, performance tuning and record locking of the File Handler
     set EXTFH=%BASESYS%\CONFIG\EXTFHBIG.CFG
rem  *
rem  * For IMS Support
     set ES_IMSLIB=%BASEAPP%\IMSLIB
     set ES_ACBLIB=%BASEAPP%\IMSLIB
rem  *
rem  * EZASOKETS Check EZASOKETS Enabled box or set ES_EZASOKET_SUPPORT=YES
     set EZACONFG=BASESYS1\CONFIG\EZACONFG.dat
rem  *
rem  * Resource Allocation and Performance for SORT and non-Relational Data
rem  set MFJSENGINE=SYNCSORT
     set SORTSCHEME=1
     set SORTSPACE=750000000
     set TMP=C:\SORTWORK
rem  *
     set ES_ALLOC_OVERRIDE=%BASESYS%\CONFIG\CATMAPA1.cfg
rem  * For CORE_ON_ERROR function, ABEND Dump
rem  *     set COBCONFIG_=%BASESYS%\CONFIG\diagnose.cfg
rem  *
rem  * Consolidated Trace Facility (CTF)
rem  *     set MFTRACE_CONFIG=%BASESYS%\CONFIG\ctf.cfg
rem  *     set MFTRACE_LOGS=c:\ctflogs
rem  *
rem  * For Job Restart, ABEND Recovery
     set MF_UCC11=Y
     set ES_JES_RESTART=Y
rem  *
rem  * Set environment for MFBSI (Micro Focus Batch Scheduling Interface)
     set ES_EMP_EXIT_1=mfbsiemx
     set MFBSI_DIR=%BASESYS%\LOGS\%JESSERVERNAME%
     set MFBSIEOP_CMD=ENABLE
     set MFBSIEOP_CSV=ENABLE
     set MFBSIEOP_HTM=ENABLE
     set MFBSIEOP_XML=ENABLE
rem  *
rem  * Set Behavior and Trace Flags for GETJOBDD
rem  *   Position=12345678/12345678
     set JDDFLAGS=nnnWnnnn/YYnnnnnn
rem  *
     set MAINFRAME_FLOATING_POINT=true
     set COBIDY=%BASEAPP%\COBIDY
     set COBPATH=.;%BASEAPP%\LOADLIB;%BASESYS%\LOADLIB;%SimoLIBR%
     set LIBPATH=.;%BASEAPP%\LOADLIB;%BASESYS%\LOADLIB;%SimoLIBR%
     set TXDIR=%BASESYS%\LOADLIB;%MIFOBASE%
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%
rem  *
rem  * If not already set then set the PATH for Micro Focus Directories
     if "%SIMOPATH%" == "Y" goto JUMPPATH
     if "%MIFOSYS1%" == "EDEV" goto JUMPEDEV
     if "%MIFOSYS1%" == "VCBL" goto JUMPVCBL
     if "%MIFOSYS1%" == "ESTU" goto JUMPESTU
     if "%MIFOSYS1%" == "EMFE" goto JUMPEMFE
:JUMPEDEV
     set path=%BASESYS%\LOADLIB;%MIFOEDEV%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOEDEV%\CPYLIB
     set MIFOBASE=%MIFOEDEV%
     goto JUMPPATH
:JUMPVCBL
     set path=%MIFOVCBL%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set MIFOBASE=%MIFOVCBL%
     goto JUMPPATH
:JUMPESTU
     set MIFOBASE=%MIFOESTU%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
:JUMPEMFE
     set MIFOBASE=%MIFOEMFE%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
rem  *
:JUMPPATH
     set SIMOPATH=Y
rem  *
     set USERCLASS=%BASELIB1%\LOADLIB
     set CLASSPATH=.
     set CLASSPATH=%CLASSPATH%;%JAVABASE%
     set CLASSPATH=%CLASSPATH%;%JAVABASE%\lib
     set CLASSPATH=%CLASSPATH%;\%USERCLASS%\simpacks
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes\simpacks
     if "%MIFOSYS1%" == "ESTU" set CLASSPATH=%CLASSPATH%;%MIFOBIN%
     if "%MIFOSYS1%" == "EDEV" set CLASSPATH=%CLASSPATH%;%MIFOEDEV%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%\mfcobol.jar
rem  *
     set JobStatus=0000
     call SimoNOTE "* Settings CmdName ENV1BASE.cmd, Version 18.09.15, %MIFOSYS1%"
     call SimoNOTE "* BaseAPP ..... %BASEAPP%"
rem *      call SimoNOTE "* MFBSIDIR .... %MFBSI_DIR% "
     call SimoNOTE "* MIFOSYS1 is %MIFOSYS1% "
     call SimoNOTE "* MIFOBASE is %MIFOBASE% "
     call SimoNOTE "* SIMOLIBR is %SIMOLIBR% "

Table of Contents Previous Section Next Section Display and Log Messages

A command file (SIMONOTE.cmd) is called from other command files to display and write messages to a log file. The following is a listing of the contents of the command file.

@echo OFF
rem  * *******************************************************************
rem  *               SIMONOTE.cmd - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *            (C) Copyright 1987-2019 All Rights Reserved            *
rem  *              Web Site URL:   http://www.simotime.com              *
rem  *                    e-mail:   helpdesk@simotime.com                *
rem  * *******************************************************************
rem  *
rem  * Text    - Display message on screen and write to a log file.
rem  * Author  - SimoTime Technologies
rem  *
rem  * This script may be called from other scripts and expects a single
rem  * parameter enclosed in double quotes. The double quotes will be
rem  * removed. Before writing to the log file a date and time stamp
rem  * will be inserted in front of the message text.
rem  *
rem  * Note: The tilde (~) removes leading/trailing double-quotes.
rem  *
if "%SimoNOTE%" == "" set SimoNOTE=c:\SimoLIBR\LOGS\SimoTime.LOG
echo %date% %time% %~1>> %SimoNOTE%
echo %~1

Table of Contents Previous Section Next Section Summary

The purpose of this document is to assist as a tutorial for new programmers or as a quick reference for experienced programmers. In the world of programming there are many ways to solve a problem. This document and the links to other documents are intended to provide a choice of alternatives.

Table of Contents Previous Section Next Section Software Agreement and Disclaimer

Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.

SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.

Table of Contents Previous Section Next Section Downloads and Links

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.

Note:  A SimoTime License is required for the items to be made available on a local system or server.

Table of Contents Previous Section Next Section Current Server or Internet Access

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.

Link to Internet   Link to Server   Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.

Link to Internet   Link to Server   Explore an Extended List of Software Technologies that are available for review and evaluation. The software technologies (or Z-Packs) provide individual programming examples, documentation and test data files in a single package. The Z-Packs are usually in zip format to reduce the amount of time to download.

Link to Internet   Link to Server   Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.

Link to Internet   Link to Server   Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and/or QSAM files.

Table of Contents Previous Section Next Section Internet Access Required

The following links will require an internet connection.

A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection

Explore The Micro Focus Web Site for more information about products and services available from Micro Focus. This link requires an Internet Connection.

Table of Contents Previous Section Next Section Glossary of Terms

Link to Internet   Link to Server   Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.

Table of Contents Previous Section Next Section Comments or Feedback

This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.

1. Send an e-mail to our helpdesk.
1.1. helpdesk@simotime.com.
2. Our telephone numbers are as follows.
2.1. 1 415 763-9430 office-helpdesk
2.2. 1 415 827-7045 mobile

We appreciate hearing from you.

Table of Contents Previous Section Next Section Company Overview

SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.

Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.

Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.

Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com


Return-to-Top
Prepare Record Layout HTML
Copyright © 1987-2019
SimoTime Technologies and Services
All Rights Reserved
When technology complements business
http://www.simotime.com