SimoGL80 - Eighty-Column Card File
|
Read from Line Sequential SimoGL80 - Eighty-Column Card File |
| When technology complements business | Copyright © 1987-2012 SimoTime Enterprises All Rights Reserved |
| The SimoTime Home Page |
This document provides a listing of the COBOL source code for a callable routine that provides read access to a Line Sequential (or ASCII/Text) file. This program is included in the SimoCARD suite of programs.
The SimoGL80 program provides an easy to use, callable routine for accessing or reading records from a line sequential file with a maximum record length of 80-bytes.
First, the pass area (or data structure) must be defined in the WORKING-STORAGE section of the program that will call SIMOGL80. A COBOL copy file is provided for this purpose and the same copy file is used in the LINKAGE section of SIMOGL80.
COPY PASSGL80.
Next, the data items in the pass area need to be initialized prior to calling SIMOGL80.
move 'OPEN ' to GL80-FILE-REQUEST
move ZERO to GL80-FILE-STATUS
move SPACES to GL80-PASS-80
Next, the following shows the line of code that makes the call to SIMOGL80.
call 'SIMOGL80' using GL80-PASS-AREA
The following is a list of the parameters required when using the GL80-PASS-AREA to call the SimoGL80 routine.
| Parameter | Description | ||||||||
| GL80-PASS-REQUEST | This parameter must be provided by the calling program.
|
||||||||
| GL80-PASS-STATUS | A zero (0) value indicates a successful completion of the request. A non-zero value indicates the request could not be completed successfully. | ||||||||
| GL80-PASS-80 | This parameter will contain the logical record for a READ request. |
Note: A listing of the COBOL copy file is provided in a following section of this document.
The SimoGL80 program that reads a record sequential file uses the file name of "GET080LS" when accessing the file. To have the program access the correct file the location and name of the physical file must be mapped to the name used by the program. This is accomplished by using an environment variable. The following shows how this is accomplished.
set GET080LS=d:\mydirectory\filename.ext
The following (SIMOGL80.CBL) is a listing of the COBOL Source Code.
IDENTIFICATION DIVISION.
PROGRAM-ID. SIMOGL80.
AUTHOR. SIMOTIME ENTERPRISES.
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
SELECT GET080LS-FILE ASSIGN TO GET080LS
ORGANIZATION IS LINE SEQUENTIAL
ACCESS MODE IS SEQUENTIAL
FILE STATUS IS GET080LS-STATUS.
*****************************************************************
DATA DIVISION.
FILE SECTION.
FD GET080LS-FILE
DATA RECORD IS GET080LS-REC.
01 GET080LS-REC.
05 GET080LS-DATA-01 PIC X(80).
*****************************************************************
WORKING-STORAGE SECTION.
01 SIM-TITLE.
05 T1 pic X(11) value '* SIMOGL80 '.
05 T2 pic X(34) value 'Sequential 80 File I/O for Reads '.
05 T3 pic X(10) value 'v06.10.17 '.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* SIMOGL80 '.
05 C2 pic X(20) value 'Copyright 1987-2012 '.
05 C3 pic X(28) value '--- SimoTime Enterprises ---'.
05 C4 pic X(20) value ' All Rights Reserved'.
01 GET080LS-STATUS.
05 GET080LS-STATUS-L pic X.
05 GET080LS-STATUS-R pic X.
01 GET080LS-EOF pic X value 'N'.
01 GET080LS-OPEN-FLAG pic X value 'C'.
*****************************************************************
* The following buffers are used to create a four-byte status *
* code that may be displayed. *
*****************************************************************
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 IO-STATUS-04.
05 IO-STATUS-0401 pic 9 value 0.
05 IO-STATUS-0403 pic 999 value 0.
01 TWO-BYTES-BINARY pic 9(4) BINARY.
01 TWO-BYTES-ALPHA redefines TWO-BYTES-BINARY.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
*****************************************************************
* Message Buffer used by the Z-DISPLAY-MESSAGE-TEXT routine. *
*****************************************************************
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* SIMOGL80 '.
05 MESSAGE-TEXT.
10 MESSAGE-TEXT-1 pic X(68) value SPACES.
10 MESSAGE-TEXT-2 pic X(188) value SPACES.
*****************************************************************
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
01 READ-FLAGS.
05 READ-1 pic X value 'Y'.
05 READ-2 pic X value 'Y'.
01 DUMP-FLAGS.
05 DUMP-ASC pic X value 'Y'.
05 DUMP-EBC pic X value 'Y'.
05 DUMP-HEX pic X value 'Y'.
01 WORK-08 pic X(8) value SPACES.
01 ASC-EBC-FLAG pic X value 'A'.
01 FIRST-TIME pic X value 'Y'.
COPY ASCEBCB1.
COPY ASCEBCB2.
*****************************************************************
LINKAGE SECTION.
COPY PASSGL80.
*****************************************************************
PROCEDURE DIVISION using GL80-PASS-AREA.
move GL80-FILE-REQUEST to WORK-08
move 'A' to ASC-EBC-FLAG
evaluate WORK-08
when 'READ ' if GET080LS-OPEN-FLAG not = 'O'
perform GET080LS-OPEN-INPUT
end-if
perform GET080LS-READ
if GET080LS-STATUS = '00'
move GET080LS-REC to GL80-PASS-80
move ZEROES to GL80-FILE-STATUS
else
move SPACES to GL80-PASS-80
perform Z-CONVERT-IO-STATUS
move IO-STATUS-04 to GL80-FILE-STATUS
end-if
when 'OPEN ' perform GET080LS-OPEN-INPUT
when 'CLOSE ' perform GET080LS-CLOSE
when 'HELP ' perform Z-POST-COPYRIGHT
when other perform TRY-EBCDIC
end-evaluate
if GET080LS-STATUS = '00'
move 0 to GL80-FILE-STATUS
else
add 4 to ZERO giving GL80-PASS-STATUS
end-if
if ASC-EBC-FLAG = 'E'
inspect GL80-PASS-STATUS converting A-INFO to E-INFO
inspect GL80-FILE-STATUS converting A-INFO to E-INFO
end-if
if FIRST-TIME = 'Y'
perform Z-POST-COPYRIGHT
display '* SimoGL80 ASC-EBC-FLAG is '
ASC-EBC-FLAG upon console
move 'N' to FIRST-TIME
end-if
GOBACK.
*****************************************************************
TRY-EBCDIC.
inspect WORK-08 converting E-INFO to A-INFO
evaluate WORK-08
when 'READ ' move 'E' to ASC-EBC-FLAG
perform GET080LS-READ
if GET080LS-STATUS = '00'
move GET080LS-REC to GL80-PASS-80
move ZEROES to GL80-FILE-STATUS
else
move SPACES to GL80-PASS-80
perform Z-CONVERT-IO-STATUS
move IO-STATUS-04 to GL80-FILE-STATUS
end-if
when 'OPEN ' move 'E' to ASC-EBC-FLAG
perform GET080LS-OPEN-INPUT
when 'CLOSE ' move 'E' to ASC-EBC-FLAG
perform GET080LS-CLOSE
when 'HELP ' move 'E' to ASC-EBC-FLAG
perform Z-POST-COPYRIGHT
when other add 16 to ZERO giving GL80-PASS-STATUS
end-evaluate
exit.
*****************************************************************
* I/O Routines for the Control File... *
*****************************************************************
GET080LS-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close GET080LS-FILE
if GET080LS-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'CLOSE Failure with GET080LS' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move GET080LS-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
GET080LS-READ.
read GET080LS-FILE
if GET080LS-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if GET080LS-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if
if APPL-AOK
CONTINUE
else
if APPL-EOF
move 'Y' to GET080LS-EOF
move GET080LS-STATUS to IO-STATUS
else
move 'READ Failure with GET080LS' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move GET080LS-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
end-if
exit.
*---------------------------------------------------------------*
GET080LS-OPEN-INPUT.
add 8 to ZERO giving APPL-RESULT.
open input GET080LS-FILE
if GET080LS-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'O' to GET080LS-OPEN-FLAG
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'OPEN Failure with GET080LS' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move GET080LS-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-ROUTINES provide administrative functions *
* for this program. *
*****************************************************************
* ABEND the program, post a message to the console and issue *
* a STOP RUN. *
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-DISPLAY-MESSAGE-TEXT
end-if
move 'PROGRAM-IS-ABENDING...' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move IO-STATUS-04 to GL80-FILE-STATUS
add 12 to ZERO giving RETURN-CODE
add 12 to ZERO giving GL80-PASS-STATUS
* GOBACK.
exit.
*****************************************************************
* Display CONSOLE messages... *
*****************************************************************
Z-DISPLAY-MESSAGE-TEXT.
if MESSAGE-TEXT-2 = SPACES
display MESSAGE-BUFFER(1:79)
else
display MESSAGE-BUFFER
end-if
move all SPACES to MESSAGE-TEXT
exit.
*****************************************************************
* Display the file status bytes. This routine will display as *
* four digits. If the full two byte file status is numeric it *
* will display as 00nn. If the 1st byte is a numeric nine (9) *
* the second byte will be treated as a binary number and will *
* display as 9nnn. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
perform Z-CONVERT-IO-STATUS
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
exit.
Z-CONVERT-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
move IO-STAT1 to IO-STATUS-04(1:1)
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
add TWO-BYTES-BINARY to ZERO giving IO-STATUS-0403
else
move '0000' to IO-STATUS-04
move IO-STATUS to IO-STATUS-04(3:2)
end-if
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE upon console
display SIM-COPYRIGHT upon console
exit.
*****************************************************************
* A product of SimoTime Enterprises *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The following (PASSGL80.CPY) is a listing of the COBOL Copy file that defines the structure for the data items in the pass area.
*****************************************************************
* Data Structure or Pass Area used for calling SIMOGL80. *
*****************************************************************
* Copyright (C) 1987-2012 SimoTime Enterprises *
* All Rights Reserved *
*****************************************************************
* Provided by SimoTime Enterprises *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
01 GL80-PASS-AREA.
05 GL80-PASS-REQUEST PIC X(8).
05 GL80-PASS-STATUS PIC 9(4).
05 GL80-FILE-REQUEST PIC X(8).
05 GL80-FILE-STATUS PIC 9(4).
05 GL80-PASS-80 PIC X(80).
*** PASSGL80 - End-of-Copy File - - - - - - - - - - - PASSGL80 *
*****************************************************************
*
The primary purpose of this document is to provide a COBOL Source member for viewing. This document may be used as a tutorial for new programmers or as a quick reference for experienced programmers. In the world of programming there are many ways to solve a problem. This document and the links to other documents are intended to provide a choice of alternatives.
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Enterprises. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Enterprises.
SimoTime Enterprises makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Enterprises shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
This section includes links to documents with additional information that is beyond the scope and purpose of this document. The first sub-section requires an internet connection, the second sub-section references locally available documents.
The following links will require an internet connect.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information.
Take a moment to check out The SimoCARD Programs that are available for review and evaluation. This document provides addtional information about processing and converting various file formats that contain 80 byte records. These files may be referred to as CARD image files, this is a carry-over from the days of 80 column cards.
Explore a set of Examples that use SIMOGL80 for additional information. This suite of programs provides multiple examples of record content conversion between EBCDIC and ASCII. File format conversion between record sequential and line sequential is included.
Explore The ASCII and EBCDIC translation tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and QSAM files.
Explore The Micro Focus Web Site for more information about products and services available from Micro Focus.
Note: You must be attached to the Internet to download a Z-Pack or view the list.
The following links may be accessible without an internet connection.
Note: A SimoTime License is required for the items to be made available on a local server.
Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and QSAM files.
Check out The SimoTime Glossary for a list of terms and definitions used in the documents provided by SimoTime.
This document was created and is maintained by SimoTime Enterprises.
If you have any questions, suggestions, comments or feedback please call or send an e-mail to: helpdesk@simotime.com
We appreciate hearing from you.
Founded in 1987, SimoTime Enterprises is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. This includes the smallest thin client using the Internet and the very large mainframe systems. There is more to making the Internet work for your company's business than just having a nice looking WEB site. It is about combining the latest technologies and existing technologies with practical business experience. It's about the business of doing business and looking good in the process. Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| SimoGL80, Read Access to a Line Sequential File |
| Copyright © 1987-2012 SimoTime Enterprises All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |