 |
|
| When technology complements business | File Transfer and Convert |
| Copyright © 1987-2008 SimoTime Enterprises, LLC All Rights Reserved | http://www.simotime.com |
|
|||||
|
The objective of this suite of programs is to provide a solution for using FTP or Shared Network Disk to transfer a mainframe sequential file with variable length records to a system that is running Microsoft Windows and Micro Focus COBOL and convert the file format to a Micro Focus sequential file with variable length records. The technique used will not require a file conversion on the ZOS Mainframe System. This example makes a call to COBOL subroutines that are part of the SimoMODS series of programs that are available from SimoTime. They are included in the Z-PACk that may be downloaded from the SimoTime Web Site.
This suite of programs covers both the transfer and file format conversion of sequential files with variable length records. Other documents are available that will focus on file processing using standard COBOL with SELECT and FD definitions. Also, HTML documentation for Mainframe File Transfer using FTP commands is available. Refer to the Downloads and Links to Similar Pages of this document for additional downloading and processing information.
Note: The called subroutines use Micro Focus functionality that is unique to Micro Focus. Therefore, a non-mainframe dialect is required when compiling the subroutines. All three (3) COBOL programs have been tested with Net Express using ASCII and a non-mainframe dialect.
This example illustrates the following functions.
| 1. | Transfer a file with variable length records from a Mainframe system to a Windows system using the File Transfer Protocol (FTP) and binary mode. |
| 2. | Use the Micro Focus Byte-Stream I/O capability to read the mainframe formatted file with variable length records. |
| 3. | Use standard COBOL coding techniques to create a Micro Focus file with variable length records. |
A mainframe formatted sequential file with variable length records is the input to this suite of programs. The input file is transferred from the Mainframe system using the File Transfer Protocol (FTP) and BINARY mode. After the file is transferred from the Mainframe system to a Windows system the file will be processed using three COBOL programs.
The input file is a binary image of the mainframe file and the file types supported by this suite of sample programs are as follows.
| Type | Description | ||||||||||||||||||
| V | Variable, if not specified the default value is 'V". The four bytes preceding the logical record is the Record Descriptor Word. The content is as follows.
|
||||||||||||||||||
| VB | Variable Blocked The four bytes preceding the logical record (Descriptor Word) are as follows.
|
||||||||||||||||||
| VBS | Variable Blocked Spanned The four bytes preceding the logical record is the Segment Descriptor Word. The content is as follows.
|
The input file that was downloaded from the mainframe is processed by a called program using byte-stream I/O. For additional information for specifying the input file type for the conversion process from a ZOS image to a Micro Focus file format refer to the Environment Variables section of this document.
The output file that is created will be a Micro Focus formatted file with variable length records. The output file is processed in the mainline COBOL program using standard COBOL coding techniques.
This suite of samples programs will run on the following platforms.
| 1. | Executes on Windows System using Micro Focus Net Express and the command files provided. |
| 2. | The programs may be ported to run on the UNIX platforms supported by Micro Focus COBOL. |
| 3. | The converted data file may be "copied to" or "accessed from" a UNIX platform supported by Micro Focus COBOL. |
| 4. | The Conversion programs were written, compiled and tested using Micro Focus Net Express, Version 5.0. The programs may be used with Net Express or Enterprise Server. The program may also be used with MFE if a non-mainframe dialect is used. |
This suite of three COBOL programs will read a mainframe formatted sequential file with variable length records. The following is a block diagram of the program and data flow. The BLUE boxes identify the data. The RED boxes identify the programs or process steps that execute on a Windows platform with Micro Focus Net Express.
|
The JCL or CMD member for running the application. | |||||||||||||||||||||||||
|
|
||||||||||||||||||||||||||
|
Delete any previously created SQEDDV01 file. | |||||||||||||||||||||||||
|
|
||||||||||||||||||||||||||
|
|
|
Read the mainframe formatted file and write the Micro Focus formatted file. | |||||||||||||||||||||||
|
|
|||||||||||||||||||||||||
|
|
End | Determine record size and prepare to get logical record | |||||||||||||||||||||||
|
|
of | ||||||||||||||||||||||||
|
|
|
|
File | Read specifies number of bytes from the file | |||||||||||||||||||||
|
|
|
|||||||||||||||||||||||||
|
The following described each of the programs in more detail.
| VRECEXC1.CBL | This is the mainline program that calls SimoVREC.CBL to process the logical records within the mainframe formatted file with variable length records. The records obtained by calling SimoVREC.CBL are then written to a file using the standard Micro Focus format for files with variable length records. The output file is accessed using the standard COBOL coding techniques with the FD, SELECT, OPEN, WRITE and CLOSE. |
| SimoVREC.CBL | This program calls SimoBSIO to read the file using byte-stream I/O. This program starts by requesting SimoBSIO to do a four byte read of the file to get the RDW (Record Descriptor Word) or SDW (Segment Descriptor Word) . Based on the content of the RDW or SDW this program will call SimoBSIO to do a read that is the length of the variable record or record segment (for VBS and record segments multiple reads may be required). The length of the record and its content is then passed back to the calling program. In this example the calling program is VRECEXC1.CBL. |
| SimoBSIO.CBL. | This program does the byte-stream I/O and is able to read the file using a single byte or a variable-length, block-of-bytes based on the request from the calling program. In this example the calling program is SimoVREC.CBL. |
The following is a sample FTP script to retrieve (or GET) a sequential file with variable-length records from a Mainframe system to a Windows system. This FTP script is for using at the client or Windows system.
userid password CD .. PWD BINARY QUOTE SITE RDW GET mainframe.dataset.name drive:\directory\filename.ext QUIT
The file must be transferred in BINARY. This will maintain the EBCDIC-encoding and the mainframe numeric formats for packed-decimal, binary and zoned-decimal data.
One of the following FTP statements must be used prior to a GET or PUT statement in order to download the Record-Descriptor-Word (RDW) and the possible Block-Descriptor-Word (BDW). The BDW and RDW are in binary format so it is critical to download in binary even if the records in the file are all text strings. Prior to a GET use one of the following statements.
QUOTE SITE RDW or LITERAL SITE RDW
If the FTP process is to be executed on the mainframe the GET statement will need to be replaced with a PUT and the QUOTE or LITERAL statement will need to be replaced with the following statement.
LOCSITE RDW
Once the file is transferred it is a mirror of the mainframe format with EBCDIC-encoding. Each record is preceded by the Record Descriptor Word (RDW) and possible Block Descriptor Word (BDW) and must be converted to a Micro Focus formatted sequential file with variable length records. This process is described in the following sections of this document.
The examples provided in this section use the three COBOL programs to convert a mainframe formatted, EBCDIC-encoded, sequential file with variable length records to a Micro Focus formatted, EBCDIC-encoded, sequential file with variable length records.
A sample Windows command file (VRECEXE1.CMD) is provided to show the steps necessary to set environment variables and map the file names used by the programs to the actual file names on the hard disk or other storage media.
@echo OFF
rem * *******************************************************************
rem * This program is provided by: *
rem * SimoTime Enterprises, LLC *
rem * (C) Copyright 1987-2006 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem *
rem * Text - Read a mainframe formatted file, write Micro Focus file.
rem * Author - SimoTime Enterprises
rem * Date - January 24, 1996
rem *
rem * The job will execute a mainline COBOL program that calls a routine
rem * that will read a mainframe formatted file with variable length
rem * records. The callable routine will use the byte-stream I/O
rem * capability provided by Micro Focus.
rem *
rem * The mainline COBOL program uses stanard COBOL file processing
rem * to write to a file that is a standard Micro Focus sequential file
rem * with variable length records.
rem *
rem * This set of programs will run on a system using Microsoft Windows
rem * and Micro Focus Net Express.
rem *
setlocal
call Env1Prod
call SimoNOTE "*******************************************************VrecExE1"
call SimoNOTE "Starting JobName VrecExE1, User is %USERNAME%"
rem *
rem * *******************************************************************
rem * Step 1, Set File Mapping using environment variables
rem *
:MapFileNames
call SimoNOTE "Identify JobStep MapFileNames"
set BSIODSN1=%BaseLib1%\DataLibA\Ftp1\FTPDDV01.DAT
set SQEDDV01=%BaseLib1%\DataLibA\Wrk1\SQEDDV01.DAT
set SYSOUT=%BaseLib1%\DataLibA\Wrk1\SYSOUTD1.TXT
rem *
rem * *******************************************************************
rem * Step 2, Delete any previously created Micro Focus formatted file
rem *
if exist %SQEDDV01% del %SQEDDV01%
rem *
rem * *******************************************************************
rem * Step 3, Read mainframe formatted sequential file using byte-stream,
rem * I/O. Create a new Micro Focus formatted sequential file.
rem * Note: the BSIOFMT1 environment variable must be set to
rem * V for Variable, VB for Variable Blocked or VBS for Variable
rem * Blocked Spanned.
rem *
:ExecuteVariableBsio
set INITREC1=E
set BSIOFMT1=V
call SimoNOTE "Identify JobStep ExecuteVariableBsio"
run VRECEXC1
if exist %SQEDDV01% call SimoNOTE "Produced DataSet %SQEDDV01%"
call SimoNOTE "Finished JobName VrecExE1, User is %USERNAME%"
:End
call SimoNOTE "Conclude SysLog is %SYSLOG%"
endlocal
if not "%1" == "nopause" pause
The following are the environment variables used to influence the behavior of the programs that access the mainframe formatted sequential files with variable length records.
| Variable | Description | ||||||||||||||||||||||||||||||||||||||||||
| INITREC1 | Must be "A" or "E" to initialize the record area with x"20" or x"40". If not specified the default value is "E". | ||||||||||||||||||||||||||||||||||||||||||
| EXTFH | Points to the EXTFH.CFG file if used. This is an optional environment variable | ||||||||||||||||||||||||||||||||||||||||||
| BSIOFMT1 | Identifies the format of the input file. The following
are the options for this environment variable.
Note 1: For a mainframe file with variable length, unblocked records each record is preceded by a four byte descriptor word. The first two bytes is a two byte binary value for the record length followed by two bytes of Low Values. By using VO the reasonability check will be bypassed. Note 2: For a mainframe file with variable length, blocked records each record is preceded by a four byte descriptor word. The first two bytes is a two byte binary value for the record length. The second part is a two byte Block Descriptor Word (BDW). By using VBO the reasonability check will be bypassed. Note 3: For a mainframe file with variable length, blocked, spanned record segments each record is preceded by a four byte Segment Descriptor Word. The first two bytes is a two byte binary value for the record segment length. The third byte is a segment control code and the fourth byte is a low value or binary 00. |
The following are the environment variables used to map the file names used by the programs to the actual file names used on the external storage media or hard disk.
| Variable | Description |
| BSIODSN1 | This is the drive:directory\filename.ext for the input file. This will map the DD name to the fully qualified PC file name. This is the mainframe formatted sequential file with variable length records. This is usually an EBCDIC encoded file with packed and binary data. |
| SEQDDV01 | This is the drive:directory\filename.ext for the output file. This will map the DD name to the fully qualified PC file name. This will be a Micro Focus formatted sequential file with variable length records. The content of the records will be the same as the input file. Only the file format is changed in this example. |
A sequential data file with variable length records that is a mirror image of a mainframe formatted file must be converted to a Micro Focus formatted file with variable length records. The file that is a mainframe image cannot be accessed at the record level using the Micro Focus Data File Editor or a COBOL program using the standard SELECT and FD syntax. Therefore, the byte-stream I/O capabilities provided by Micro Focus will be used to read this file.
The following program (VRECEXC1.CBL) will read the mainframe file by calling the SIMOVREC.CBL program. SIMOVREC.CBL will call SIMOBSIO.CBL to read text strings from the mainframe file and build logical records to pass back to the following program. The following program will then use standard COBOL coding techniques to write the records to a Micro Focus formatted file.
IDENTIFICATION DIVISION.
PROGRAM-ID. VRECEXC1.
AUTHOR. SIMOTIME ENTERPRISES.
*****************************************************************
* Source Member: VRECEXC1.CBL
* Copy Files: PASSRTN1.CPY
* ASCEBCB1.CPY
* Calls to: SIMOBSIO
*****************************************************************
*
* ************
* * VRECEXE1 *
* ********cmd*
* *
* ************
* * if exist *
* ********stmt*
* *
* ************ ************ ************
* * BSIODSN1 *-----* VRECEXC1 *-----* SQEDDV01 *
* ********dat* ********cbl* ********dat*
* * *
* * * ************
* * *--call-* SIMOVREC *
* * ********cbl*
* * *
* * * ************
* * *--call-* SIMOBSIO *
* * ********cbl*
* ************
* * EOJ *
* ************
*
*****************************************************************
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
SELECT SQEDDV01-FILE ASSIGN to SQEDDV01
ORGANIZATION is SEQUENTIAL
ACCESS MODE is SEQUENTIAL
FILE STATUS is SQEDDV01-STATUS.
*****************************************************************
DATA DIVISION.
FILE SECTION.
FD SQEDDV01-FILE
DATA RECORD is SQEDDV01-RECORD
RECORDING MODE is V
* The following may need to be changed to match actual file.
RECORD is VARYING in SIZE from 4 to 32760
depending on SQEDDV01-LREC.
01 SQEDDV01-RECORD.
05 SQEDDV01-DATA-01 pic X(32760).
WORKING-STORAGE SECTION.
01 SIM-TITLE.
05 T1 pic X(11) value '* VRECEXC1 '.
05 T2 pic X(34) value 'Variable Record Routine v01.00.00 '.
05 T3 pic X(10) value ' v06.10.23'.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* VRECEXC1 '.
05 C2 pic X(20) value 'Copyright 1987-2006 '.
05 C3 pic X(28) value ' SimoTime Enterprises, LLC '.
05 C4 pic X(20) value ' All Rights Reserved'.
01 SIM-THANKS-01.
05 C1 pic X(11) value '* VRECEXC1 '.
05 C2 pic X(32) value 'Thank you, this technology was p'.
05 C3 pic X(32) value 'roduced at SimoTime Enterprises,'.
05 C4 pic X(04) value ' LLC'.
01 SIM-THANKS-02.
05 C1 pic X(11) value '* VRECEXC1 '.
05 C2 pic X(32) value 'Please send all inquires or sugg'.
05 C3 pic X(32) value 'estions to the helpdesk@simotime'.
05 C4 pic X(04) value '.com'.
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* VRECEXC1 '.
05 MESSAGE-TEXT.
10 MESSAGE-TEXT-1 pic X(68) value SPACES.
10 MESSAGE-TEXT-2 pic X(188) value SPACES.
01 SQEDDV01-STATUS.
05 SQEDDV01-STATUS-L pic X.
05 SQEDDV01-STATUS-R pic X.
01 SQEDDV01-EOF pic X value 'N'.
01 SQEDDV01-OPEN-FLAG pic X value 'C'.
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 TWO-BYTES.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
01 TWO-BYTES-BINARY redefines TWO-BYTES pic 9(4) comp.
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
01 SQEDDV01-LREC pic 9(5) comp value 0.
01 SQEDDV01-LREC-ALPHA redefines SQEDDV01-LREC.
05 VREC-LEN-1 pic X(2).
05 VREC-LEN-2 pic X(2).
01 SQEDDV01-LBLK pic 9(5) comp value 0.
01 SQEDDV01-LBLK-ALPHA redefines SQEDDV01-LBLK.
05 VBLK-LEN-1 pic X(2).
05 VBLK-LEN-2 pic X(2).
01 RECORD-LENGTH-DISPLAY.
05 filler pic X(15) value 'Record length: '.
05 RECORD-LENGTH-VALUE pic 9(5) value 0.
01 RECORD-MIN-DISPLAY.
05 filler pic X(15) value 'Record MIN is: '.
05 RECORD-MIN-VALUE pic 9(4) value 0.
01 RECORD-MAX-DISPLAY.
05 filler pic X(15) value 'Record MAX is: '.
05 RECORD-MAX-VALUE pic 9(4) value 0.
01 BSIOREAD-TOTAL.
05 filler pic X(18) value 'BSIOREAD count is '.
05 BSIOREAD-COUNT pic 9(7) value 0.
01 BSIOBLOK-TOTAL.
05 filler pic X(18) value 'BSIOBLOK count is '.
05 BSIOBLOK-COUNT pic 9(7) value 0.
01 SQEDDV01-TOTAL.
05 filler pic X(18) value 'SQEDDV01 count is '.
05 SQEDDV01-COUNT pic 9(7) value 0.
COPY PASSVREC.
*01 PASSVREC-AREA.
* 05 VREC-REQUEST pic X(8) value 'GET '.
* 05 VREC-RESPOND pic 9(4) value 0.
* 05 VREC-LENGTH pic 9(5) value 0.
* 05 VREC-BUFFER pic X(32760) value SPACES.
*****************************************************************
PROCEDURE DIVISION.
perform GET-STARTED
perform SQEDDV01-OPEN
add 80 to ZERO giving SQEDDV01-LREC
perform until VREC-RESPOND not = ZERO
call 'SIMOVREC' using PASSVREC-AREA
if VREC-RESPOND = ZERO
add VREC-LENGTH to ZERO giving SQEDDV01-LREC
move VREC-BUFFER to SQEDDV01-RECORD
perform SQEDDV01-WRITE
end-if
end-perform
perform SQEDDV01-CLOSE
perform Z-THANK-YOU.
GOBACK.
*****************************************************************
GET-STARTED.
perform Z-POST-COPYRIGHT
move 'GET ' to VREC-REQUEST
move ZERO to VREC-RESPOND
move ZERO to VREC-LENGTH
move SPACES to VREC-BUFFER
exit.
*****************************************************************
* I/O ROUTINES FOR SQEDDV01... *
*****************************************************************
SQEDDV01-WRITE.
if SQEDDV01-OPEN-FLAG = 'C'
perform SQEDDV01-OPEN
end-if
write SQEDDV01-RECORD
if SQEDDV01-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if SQEDDV01-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if.
if APPL-AOK
CONTINUE
else
move 'SQEDDV01-Failure-WRITE...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move SQEDDV01-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
SQEDDV01-OPEN.
add 8 to ZERO giving APPL-RESULT.
open output SQEDDV01-FILE
if SQEDDV01-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'O' to SQEDDV01-OPEN-FLAG
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'SQEDDV01-Failure-OPEN...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move SQEDDV01-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
SQEDDV01-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close SQEDDV01-FILE
if SQEDDV01-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'C' to SQEDDV01-OPEN-FLAG
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'SQEDDV01-Failure-CLOSE...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move SQEDDV01-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-Routines perform administrative tasks *
* for this program. *
*****************************************************************
* ABEND the program, post a message to the console and issue *
* a STOP RUN. *
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-DISPLAY-CONSOLE-MESSAGE
end-if
move 'PROGRAM-IS-ABENDING...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
add 12 to ZERO giving RETURN-CODE
STOP RUN.
* exit.
*****************************************************************
* Display CONSOLE messages... *
*****************************************************************
Z-DISPLAY-CONSOLE-MESSAGE.
if MESSAGE-TEXT-2 = SPACES
display MESSAGE-BUFFER(1:79)
else
display MESSAGE-BUFFER
end-if
move all SPACES to MESSAGE-TEXT
exit.
*****************************************************************
* Display the file status bytes. This routine will display as *
* two digits if the full two byte file status is numeric. If *
* second byte is non-numeric then it will be treated as a *
* binary number. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
display '* VRECEXC1 File-Status-' IO-STAT1 '/'
TWO-BYTES-BINARY
else
display '* VRECEXC1 File-Status-' IO-STATUS
end-if
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE
display SIM-COPYRIGHT
exit.
*****************************************************************
Z-THANK-YOU.
display SIM-THANKS-01
display SIM-THANKS-02
exit.
*****************************************************************
* This example is provided by SimoTime Enterprises *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The purpose of this document is to show how to transfer a file from a mainframe using File Transfer Protocol (FTP). The mainframe file is an EBCDIC-encoded, sequential file with variable length records. Once the file is transferred the file format will be converted to a Micro Focus formatted file with variable length records. The content of the records will remain EBCDIC encoded.
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Enterprises. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Enterprises.
SimoTime Enterprises makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any express or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Enterprises shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
You may download this example at http://www.simotime.com/sim4dzip.htm#QsamFileConvertVrecEx01Zip as a Z-Pack. The Z-Packs provide individual programming examples, documentation and test data files in a single package. The Z-Packs are usually in zip format to reduce the amount of time to download. Please view the complete list of SimoTime Z-Pack Examples at http://www.simotime.com/sim4dzip.htm.
The mainline program used in this example makes calls to two (2) additional modules that are part of the SimoMODS series of commonly used subroutines. To view the source code for the called members refer to simovrec.htm and simobsio.htm.
To process a file with variable length records after it has been downloaded from the mainframe and converted to a Micro Focus file format refer to the cblv8001.htm. This example focusing on file processing using standard COBOL dialect with the SELECT and FD statements.
This document provides a quick summary of the FTP Commands for transferring sequential files from a Mainframe System to a Windows System.
Check out The VSAM - QSAM Connection for more examples of mainframe VSAM and QSAM accessing techniques and sample code.
This document provides a quick summary of the File Status Key for VSAM data sets and QSAM files.
Check out The SimoTime Library for a wide range of topics for Programmers, Project Managers and Software Developers.
To review all the information available on this site start at The SimoTime Home Page .
Check out The SimoTime Glossary for a list of terms and definitions used in the documents provided by SimoTime.
If you have any questions, suggestions or comments please call or send an e-mail to: helpdesk@simotime.com
We appreciate your comments and feedback.
Founded in 1987, SimoTime Enterprises is a privately owned, Limited Liability Corporation located in Novato, California. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. This includes the smallest thin client using the Internet and the very large mainframe systems. There is more to making the Internet work for your company's business than just having a nice looking WEB site. It is about combining the latest technologies and existing technologies with practical business experience. It's about the business of doing business and looking good in the process. Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| Copyright © 1987-2008 SimoTime Enterprises, LLC All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |
| Version 07.01.01 |