Access a VSAM Key Sequenced Data Set (KSDS)
|
COBOL and VSAM Access a VSAM Key Sequenced Data Set (KSDS) |
| When technology complements business | Copyright © 1987-2012 SimoTime Enterprises All Rights Reserved |
| The SimoTime Home Page |
This suite of programs provides an example of how a single mainline COBOL program accesses a VSAM data set. The COBOL program is written using COBOL/2 dialect but also works with COBOL for MVS, COBOL/370 and COBOL for 390. A JCL member is provided to run the job as an MVS or OS.390 batch job on an IBM mainframe or as a project with Micro Focus Mainframe Express (MFE) running on a PC with Windows.
This program may serve as a tutorial for programmers that are new to COBOL or VSAM and as a reference for experienced programmers.
This example illustrates the following functions.
| ||||||||||||||
| Sample Job to Execute a COBOL Program that Accesses a VSAM, KSDS |
This suite of samples programs will run on the following platforms.
| ||||||||
| Requirements for Operating System and Supporting Software |
The following is a flowchart of the job for executing the VSAM access program.
| ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
| Accessing a VSAM, KSDS from a COBOL Program |
Note: The light-green boxes are unique to the Mainframe and Micro Focus Enterprise Server/Studio (or Micro Focus Mainframe Express). The light-red boxes are unique to the PC with Windows and Micro Focus. The light-yellow boxes are decision points or program transitions in the processing logic. The light-blue boxes identify data structures such as Files, VSAM Data Sets or Relational Tables. The light-gray boxes identify a system function or information item.
The following is the Windows Command file (CBLVSME1.CMD) required to run as a MVS batch job on the PC. This process was tested on the PC with Micro Focus Net Express.
@echo OFF
rem * ************************************************************************
rem * CBLVSME1.CMD - a Windows Command File *
rem * This program is provided by SimoTime Enterprises *
rem * (C) Copyright 1987-2012 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * ************************************************************************
rem *
rem * Text - COBOL for VSAM, KSDS processing
rem * Author - SimoTime Enterprises
rem * Date - January 01, 1997
rem *
rem * This set of programs illustrates the use of COBOL programs
rem * to do VSAM, Keyed-Sequential-Data-Set I/O.
rem *
rem * The COBOL programs are compiled with the ASSIGN(EXTERNAL) and
rem * the CHARSET(EBCDIC) directives. This provides for external
rem * file mapping of the file names. The CHARSET(EBCDIC) allows for the
rem * processing of the EBCDIC data from the VSAM, KSDS
rem * This technique provides for the use of a single COBOL source
rem * program that will run on OS/390, Windows or Unix.
rem *
rem * This set of programs will run on a Personal Computer with Windows
rem * and Micro Focus Net Express.
rem *
rem * ************
rem * * CblVsmJ1 *
rem * ********jcl*
rem * *
rem * *
rem * ************ ************ ************
rem * * VKSD0080 ******* CblVsmC1 ******* Console *
rem * ********dat* ********cbl* ********crt*
rem * *
rem * *
rem * ************
rem * * EOJ *
rem * ************
rem *
rem * *******************************************************************
rem * Step 1 of 2 Set the global environment variables...
rem *
call ..\Env1BASE
set CmdName=CBLVSME1
rem *
call SimoNOTE "*******************************************************%CmdName%.CMD"
call SimoNOTE "Starting JobName %CmdName%.CMD"
rem *
set CUSKS080=%BaseLib1%\DataLibA\Asc1\SIMOTIME.DATA.CUST0080.DAT
run CblVsmC1
if not "%ERRORLEVEL%" == "0" set JobStatus=0010
if not "%JobStatus%" == "0000" goto :EojNOK
goto EojAok
:EojAOK
call SimoNOTE "Finished CmdName %CmdName%, Job Status is %JobStatus%"
goto :End
:EojNOK
call SimoNOTE "ABENDING CmdName %CmdName%, Job Status is %JobStatus%"
echo %DATE% - %TIME% Starting User ABEND Processing...>>%SYSLOG%
set >>%SYSLOG%
echo %DATE% - %TIME% Complete User ABEND Processing...>>%SYSLOG%
goto :End
:End
call SimoNOTE "Conclude SysOut is %SYSOUT%"
if not "%1" == "nopause" pause
exit /B %JobStatus%
The following is the mainframe JCL (CBLVSMJ1.JCL) required to run as an MVS batch job on the mainframe. This will also run on the PC with Micro Focus Mainframe Express. The coding technique is used with the expectation the JCL would be used as a stand alone procedure.
//CBLVSMJ1 JOB SIMOTIME,ACCOUNT,CLASS=1,MSGCLASS=0,NOTIFY=CSIP1, // COND=(0,LT) //* ******************************************************************* //* This program is provided by: SimoTime Enterprises * //* (C) Copyright 1987-2012 All Rights Reserved * //* Web Site URL: http://www.simotime.com * //* e-mail: helpdesk@simotime.com * //* ******************************************************************* //* //* Text - COBOL for VSAM I/O //* Author - SimoTime Enterprises //* Date - January 01, 1997 //* //* This set of programs illustrates the use of a COBOL program //* to do VSAM sequential I/O. The purpose is to show the processing //* of a VSAM Keyed Sequential Data Set (KSDS). //* //* This set of programs will run on a mainframe under MVS or on a //* Personal Computer with Windows and Micro Focus Mainframe Express. //* //* ************ //* * CBLVSMJ1 * //* ********JCL* //* * //* * //* ************ ************ ************ //* * VKSD0080 *-----* CBLVSMC1 *-----* CONSOLE * //* ********DAT* ********CBL* ********DAT* //* * //* * //* ************ //* * EOJ * //* ************ //* //* ******************************************************************* //* Step 1 of 1 This is a single step job. //* ******************************************************************* //* //CBLVSMX1 EXEC PGM=CBLVSMC1 //STEPLIB DD DSN=SIMOTIME.DEMO.LOADLIB1,DISP=SHR //VKSD0080 DD DSN=SIMOTIME.DATA.VKSD0080,DISP=SHR //SYSOUT DD SYSOUT=* //*
This program (CBLVSMC1.CBL) was written to be used as a teaching and learning aid. It is a simple program that reads a VSAM, Keyed-Sequential-Data-Set (KSDS) and displays the records. Notice the "Z-DISPLAY-IO-STATUS" routine to display the file status code.
IDENTIFICATION DIVISION.
PROGRAM-ID. CBLVSMC1.
AUTHOR. SIMOTIME ENTERPRISES.
*****************************************************************
* Copyright (C) 1987-2012 SimoTime Enterprises. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Enterprises. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Enterprises. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Enterprises. *
* *
* SimoTime Enterprises makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Enterprises shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Enterprises *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Enterprises, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Enterprises *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
*****************************************************************
* Source Member: CBLVSMC1.CBL
*****************************************************************
*
* CBLVSMC1 -This is an example of a single COBOL program that
* accesses a VSAM Keyed Sequential Data Set (KSDS).
*
* EXECUTION OR CALLING PROTOCOL
* -----------------------------
* Use standard mainframe JCL to EXECUTE or ANIMATE.
*
* DESCRIPTION
* -----------
* This program uses standard COBOL syntax to access a VSAM
* Keyed Sequential Data Set (KSDS).
*
* ************
* * CBLVSMJ1 *
* ********jcl*
* *
* *
* ************ ************ ************
* * CUSKS080 *-----* CBLVSMC1 *-----* CONSOLE *
* *******vsam* ********cbl* ******dsply*
*
*
* REQUIREMENTS
* ------------
* This program was originally written to conform to the IBM,
* COBOL II dialect but will work with COBOL for MVS or COBOL/390.
* This program may also be executed on the PC using Mainframe
* Express (MFE) from Micro Focus.
*
*****************************************************************
*
* MAINTENANCE
* -----------
* 1997/02/27 Simmons, Created program.
* 1997/02/27 Simmons, No changes to date.
* 1998/11/10 Simmons, Modified to conform to COBOL II.
* 1998/11/21 Simmons, Added code to display file status when an
* I/O error occurs.
*
*****************************************************************
*
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
SELECT CUSKS080-FILE
ASSIGN to CUSKS080
ORGANIZATION is INDEXED
ACCESS MODE is SEQUENTIAL
RECORD KEY is CUSKS080-KEY
FILE STATUS is CUSKS080-STATUS.
*
DATA DIVISION.
FILE SECTION.
FD CUSKS080-FILE.
01 CUSKS080-RECORD.
05 CUSKS080-KEY pic X(6).
05 CUSKS080-DATA pic X(74).
WORKING-STORAGE SECTION.
*****************************************************************
* Data-structure for Title and Copyright...
* ------------------------------------------------------------
01 SIM-TITLE.
05 T1 pic X(11) value '* CBLVSMC1 '.
05 T2 pic X(34) value 'Sample, COBOL for VSAM I/O '.
05 T3 pic X(10) value ' v08.01.04'.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* CBLVSMC1 '.
05 C2 pic X(20) value 'Copyright 1987-2012 '.
05 C3 pic X(28) value '--- SimoTime Enterprises ---'.
05 C4 pic X(20) value ' All Rights Reserved'.
01 SIM-THANKS-01.
05 C1 pic X(11) value '* CBLVSMC1 '.
05 C2 pic X(32) value 'Thank you for using this softwar'.
05 C3 pic X(32) value 'e provided from SimoTime Enterpr'.
05 C4 pic X(04) value 'ises'.
01 SIM-THANKS-02.
05 C1 pic X(11) value '* CBLVSMC1 '.
05 C2 pic X(32) value 'Please send all inquires or sugg'.
05 C3 pic X(32) value 'estions to the helpdesk@simotime'.
05 C4 pic X(04) value '.com'.
*****************************************************************
01 CUSKS080-STATUS.
05 CUSKS080-STAT1 pic X.
05 CUSKS080-STAT2 pic X.
*****************************************************************
* The following buffers are used to create a four-byte numeric *
* file status code that may be displayed. *
*****************************************************************
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 TWO-BYTES-BINARY pic 9(4) BINARY.
01 TWO-BYTES-ALPHA redefines TWO-BYTES-BINARY.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
01 IO-STATUS-04.
05 IO-STATUS-0401 pic 9 value 0.
05 IO-STATUS-0403 pic 999 value 0.
*****************************************************************
* Buffer used for posting messages to the console.
*****************************************************************
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* CBLVSMC1 '.
05 MESSAGE-TEXT.
10 MESSAGE-TEXT-1 pic X(68) value SPACES.
10 MESSAGE-TEXT-2 pic X(188) value SPACES.
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
01 END-OF-FILE pic X(3) value 'NO '.
*****************************************************************
PROCEDURE DIVISION.
perform Z-POST-COPYRIGHT.
perform CUSKS080-OPEN.
perform until END-OF-FILE = 'YES'
if END-OF-FILE = 'NO '
perform CUSKS080-GET-NEXT
if END-OF-FILE = 'NO '
display CUSKS080-RECORD upon console
end-if
end-if
end-perform.
perform CUSKS080-CLOSE.
move 'NORMAL-END-OF-JOB...' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
perform Z-THANK-YOU.
GOBACK.
*****************************************************************
* I/O routines to access a KSDS, VSAM Data Set... *
*****************************************************************
CUSKS080-GET-NEXT.
read CUSKS080-FILE.
if CUSKS080-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if CUSKS080-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if
if APPL-AOK
CONTINUE
else
if APPL-EOF
move 'YES' to END-OF-FILE
else
move 'CUSKS080-FAILURE-GET-!!!' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move CUSKS080-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
end-if
exit.
*---------------------------------------------------------------*
CUSKS080-OPEN.
add 8 to ZERO giving APPL-RESULT.
open input CUSKS080-FILE
if CUSKS080-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'CUSKS080-FAILURE-OPEN-!!!' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move CUSKS080-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
CUSKS080-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close CUSKS080-FILE
if CUSKS080-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'CUSKS080-FAILURE-CLOSE-!!!' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move CUSKS080-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-Routines perform administrative functions
* for this program.
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-DISPLAY-MESSAGE-TEXT
end-if
move 'PROGRAM IS ABENDING !!!' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
add 12 to ZERO giving RETURN-CODE
STOP RUN.
* exit.
*****************************************************************
* Display the file status bytes. This routine will display as *
* four digits. If the full two byte file status is numeric it *
* will display as 00nn. If the 1st byte is a numeric nine (9) *
* the second byte will be treated as a binary number and will *
* display as 9nnn. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
move IO-STAT1 to IO-STATUS-04(1:1)
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
add TWO-BYTES-BINARY to ZERO giving IO-STATUS-0403
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
else
move '0000' to IO-STATUS-04
move IO-STATUS to IO-STATUS-04(3:2)
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
end-if
exit.
*****************************************************************
* Display CONSOLE messages... *
*****************************************************************
Z-DISPLAY-MESSAGE-TEXT.
if MESSAGE-TEXT-2 = SPACES
display MESSAGE-BUFFER(1:79) upon console
else
display MESSAGE-BUFFER upon console
end-if
move all SPACES to MESSAGE-TEXT
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE upon console
display SIM-COPYRIGHT upon console
exit.
*****************************************************************
Z-THANK-YOU.
display SIM-THANKS-01 upon console
display SIM-THANKS-02 upon console
exit.
*****************************************************************
* This example is provided by SimoTime Enterprises *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The purpose of this document is to assist as a tutorial for new programmers or as a quick reference for experienced programmers. In the world of programming there are many ways to solve a problem. This document and the links to other documents are intended to provide a choice of alternatives.
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Enterprises. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Enterprises.
SimoTime Enterprises makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Enterprises shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
This section includes links to documents with additional information that is beyond the scope and purpose of this document. The first sub-section requires an internet connection, the second sub-section references locally available documents.
Note: A SimoTime License is required for the items to be made available on a local server.
The following links will require an internet connect.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information.
This suite of programs and documentation is available for download. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
To create the VSAM data set used by this example refer to the utility programs that Define and Populate a VSAM, KSDS with customer information.
Explore The ASCII and EBCDIC translation tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and QSAM files.
Explore The Micro Focus Web Site for more information about products and services available from Micro Focus.
The following links may be accessible without an internet connection.
Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and QSAM files.
Check out The SimoTime Glossary for a list of terms and definitions used in the documents provided by SimoTime.
This document was created and is maintained by SimoTime Enterprises.
If you have any questions, suggestions, comments or feedback please call or send an e-mail to: helpdesk@simotime.com
We appreciate hearing from you.
Founded in 1987, SimoTime Enterprises is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. This includes the smallest thin client using the Internet and the very large mainframe systems. There is more to making the Internet work for your company's business than just having a nice looking WEB site. It is about combining the latest technologies and existing technologies with practical business experience. It's about the business of doing business and looking good in the process. Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| COBOL and VSAM, access a VSAM Key Sequenced Data Set (KSDS) |
| Copyright © 1987-2012 SimoTime Enterprises All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |